File Coverage

blib/lib/Dancer2/Core/Request/Upload.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	5	6	83.3
condition			n/a
subroutine	11	11	100.0
pod	6	6	100.0
total	57	58	98.2

package Dancer2::Core::Request::Upload;
# ABSTRACT: Class representing file upload requests
$Dancer2::Core::Request::Upload::VERSION = '2.1.0';
use Moo;

use Carp;
use Path::Tiny ();
use File::Copy ();

use Dancer2::Core::Types;

has filename => (
    is  => 'ro',
    isa => Str,
);

has tempname => (
    is  => 'ro',
    isa => Str,
);

has headers => (
    is  => 'ro',
    isa => HashRef,
);

has size => (
    is  => 'ro',
    isa => Num,
);

sub file_handle {
    my ($self) = @_;
    return $self->{_fh} if defined $self->{_fh};
    $self->{_fh} = Path::Tiny::path( $self->tempname )->openr_raw;
}

sub copy_to {
    my ( $self, $target ) = @_;
    File::Copy::copy( $self->tempname, $target );
}

sub link_to {
    my ( $self, $target ) = @_;
    CORE::link( $self->tempname, $target );
}

sub content {
    my ( $self, $layer ) = @_;
    return $self->{_content}
      if defined $self->{_content};

    $layer = ':raw' unless $layer;

    my $content = undef;
    my $handle  = $self->file_handle;

    binmode( $handle, $layer );

    while ( $handle->read( my $buffer, 8192 ) ) {
        $content .= $buffer;
    }

    $self->{_content} = $content;
}

sub basename {
    my ($self) = @_;
    return Path::Tiny::path( $self->filename )->basename;
}

sub type {
    my $self = shift;
    return $self->headers->{'Content-Type'};
}

1;

__END__