File Coverage

blib/lib/Dancer/Template/Handlebars.pm

Criterion	Covered	Total	%
statement	47	51	92.1
branch	10	14	71.4
condition	2	3	66.6
subroutine	13	14	92.8
pod	5	6	83.3
total	77	88	87.5

package Dancer::Template::Handlebars;
BEGIN {
  $Dancer::Template::Handlebars::AUTHORITY = 'cpan:YANICK';
}
# ABSTRACT: Wrapper for the Handlebars template system
$Dancer::Template::Handlebars::VERSION = '0.2.1';

use strict;
use warnings;

use Dancer::Config 'setting';

use Text::Handlebars;

use Moo;
extends 'Dancer::Template::Abstract';

has views_root => (
    is => 'ro',
    lazy => 1,
    default => sub {
        Dancer::App->current->setting('views')
    },
);

has helpers => (
    is => 'ro',
    lazy => 1,
    builder => '_build_helpers',
);

sub _build_helpers {
    my $self = shift;

    my %helpers;

    if ( my $h = $self->config->{helpers} ) {
        for my $module ( ref $h ? @$h : $h ) {
            my %h = eval "use $module; %".$module.'::HANDLEBARS_HELPERS';

            die "couldn't import helper functions from $module: $@" if $@;

            @helpers{ keys %h } = values %h;
        }
    }

    return \%helpers;
}

has _engine => (
    is => 'ro',
    lazy => 1,
    default => sub {
        my $self = shift;

        return Text::Handlebars->new(
            path => [
                $self->views_root
            ],
            %{ $self->config },
            helpers => $self->helpers,
        );
    },
);

sub gather_helpers {
    my( $self, $modules ) = @_;

}


sub default_tmpl_ext { "hbs" }

sub view {
    my ($self, $view) = @_;

    return $view if ref $view;

    for my $view_path ($self->_template_name($view)) {
        return $view_path if -f join '/', $self->views_root, $view_path;
    }

    # No matching view path was found
    return;
}

sub layout {
    my ($self, $layout, $tokens, $content) = @_;

    my $dir = Dancer::App->current->setting('views');
    my( $layout_name ) = grep { -e join '/', $dir, $_ }
                          map { 'layouts/'.$_ } $self->_template_name($layout);

    my $full_content;
    if (-e join '/', $dir, $layout_name ) {
        $full_content = Dancer::Template->engine->render(
                                     $layout_name, {%$tokens, content => $content});
    } else {
        $full_content = $content;
        Dancer::Logger::error("Defined layout ($layout) was not found!");
    }
    $full_content;
}

sub view_exists {
    my( $self, $template) = @_;

    # string ref or file
    return ref($template) || -f join '/', $self->views_root, $template;

}

sub render {
    my ($self, $template, $tokens) = @_;

    if ( ref $template ) {
        return $self->_engine->render_string( $$template, $tokens );
    }

    return $self->_engine->render( $template, $tokens );

}

1;

__END__