File Coverage

lib/Dancer/Plugin/Ajax.pm

Criterion	Covered	Total	%
statement	25	37	67.5
branch	2	8	25.0
condition			n/a
subroutine	6	7	85.7
pod			n/a
total	33	52	63.4

package Dancer::Plugin::Ajax;
our $AUTHORITY = 'cpan:SUKRIA';
#ABSTRACT: a plugin for adding Ajax route handlers
$Dancer::Plugin::Ajax::VERSION = '1.3514_04'; # TRIAL
$Dancer::Plugin::Ajax::VERSION = '1.351404';
use strict;
use warnings;

use Dancer ':syntax';
use Dancer::Exception ':all';
use Dancer::Plugin;

register 'ajax' => \&ajax;

hook before => sub {
    if (request->is_ajax) {
        content_type( plugin_setting->{content_type} || 'text/xml' );
    }
};

sub ajax {
    my ($pattern, @rest) = @_;

    my $code;
    for my $e (@rest) { $code = $e if (ref($e) eq 'CODE') }

    my $ajax_route = sub {
        # must be an XMLHttpRequest
        if (not request->is_ajax) {
            pass and return 0;
        }

        # disable layout
        my $layout = setting('layout');
        setting('layout' => undef);
        my $response = try {
            $code->();
        } catch {
            my $e = $_;
            setting('layout' => $layout);
            die $e;
        };
        setting('layout' => $layout);
        return $response;
    };

    # rebuild the @rest array with the compiled route handler
    my @compiled_rest;
    for my $e (@rest) {
        if (ref($e) eq 'CODE') {
            push @compiled_rest, {ajax => 1}, $ajax_route;
        }
        else {
            push @compiled_rest, {ajax => 1}, $e;
        }
    }

    any ['get', 'post'] => $pattern, @compiled_rest;
}

register_plugin;
1;

__END__