File Coverage

blib/lib/DDG/Block.pm

Criterion	Covered	Total	%
statement	74	83	89.1
branch	21	30	70.0
condition			n/a
subroutine	13	15	86.6
pod	5	8	62.5
total	113	136	83.0

package DDG::Block;
our $AUTHORITY = 'cpan:DDG';
# ABSTRACT: Block to bundle plugins with triggers
$DDG::Block::VERSION = '1017';
use Moo::Role;
use Carp;
use Class::Load ':all';
use POSIX qw(strftime);

requires qw(
	request
);

sub BUILD {
	my ( $self ) = @_;
	$self->_plugin_objs;
	$self->trace('Loaded block',
		ref $self,
		map {
			$_.':'.( $self->$_ ? 1 : 0 ),
		} qw( return_one allow_missing_plugins allow_duplicate ),
	);
}


has plugins => (
	#isa => 'ArrayRef[Str|HashRef]',
	is => 'ro',
	lazy => 1,
	builder => '_build_plugins',
);

sub _build_plugins { die (ref shift)." requires plugins" }


has allow_missing_plugins => (
	#isa => 'Bool',
	is => 'ro',
	default => sub { 0 },
);


has return_one => (
	#isa => 'Bool',
	is => 'ro',
	default => sub { 1 },
);


has allow_duplicate => (
	#isa => 'Bool',
	is => 'ro',
	default => sub { 0 },
);


has debug_trace => (
	#isa => 'Bool',
	is => 'ro',
	default => sub { defined $ENV{DDG_BLOCK_TRACE} && $ENV{DDG_BLOCK_TRACE} ? 1 : 0 },
);

sub trace {
	my $self = shift;
	return unless $self->debug_trace;
	print STDERR ("[".$self->trace_name."] ",join(" ",map { defined $_ ? $_ : 'undef' } @_),"\n");
}

sub trace_name { ref(shift) }


has before_build => (
	#isa => 'CodeRef',
	is => 'ro',
	predicate => 'has_before_build',
);


has after_build => (
	#isa => 'CodeRef',
	is => 'ro',
	predicate => 'has_after_build',
);


has _plugin_objs => (
	# like ArrayRef[ArrayRef[$trigger,DDG::Block::Plugin]]',
	is => 'ro',
	lazy => 1,
	builder => '_build__plugin_objs',
);
sub plugin_objs { shift->_plugin_objs }

sub _build__plugin_objs {
	my ( $self ) = @_;
	my @plugin_objs;
	for (@{$self->plugins}) {
		my $class;
		my %args;
		if (ref $_ eq 'HASH') {
			croak "require a class key in hash" unless defined $_->{class};
			$class = delete $_->{class};
			%args = %{$_};
		} else {
			$class = $_;
		}
		my $plugin;
		if (ref $class) {
			$plugin = $class;
		} else {
			unless (try_load_class($class)) {
				if ($self->allow_missing_plugins) {
					if (ref $self->allow_missing_plugins eq 'CODE') {
						$self->allow_missing_plugins->($self,$class);
					}
				} else {
					die "Can't load plugin ".$class;
				}
				next;
			}
			$args{block} = $self;
			if ($self->has_before_build) {
				for ($class) {
					$self->before_build->($self,$class);
				}
			}
			$plugin = $class->new(\%args);
		}
		if ($self->has_after_build) {
			for ($plugin) {
				$self->after_build->($self,$plugin);
			}
		}
		my @triggers = $self->get_triggers_of_plugin($plugin);
		@triggers = $self->empty_trigger unless @triggers;
		my @parsed_triggers;
		for (@triggers) {
			push @parsed_triggers, $self->parse_trigger($_);
		}
		push @plugin_objs, [
			\@parsed_triggers,
			$plugin,
		] if @parsed_triggers;
	}
	return \@plugin_objs;
}


has only_plugin_objs => (
	is => 'ro',
	lazy => 1,
	builder => '_build_only_plugin_objs',
);
sub _build_only_plugin_objs {
	my ( $self ) = @_;
	my @plugins;
	for (@{$self->_plugin_objs}) {
		push @plugins, $_->[1];
	}
	return \@plugins;
}


sub get_triggers_of_plugin { shift; shift->get_triggers }


sub parse_trigger { shift; shift; }


sub empty_trigger { return undef }


sub handle_request_matches {
	my ( $self, $plugin, $request, @args ) = @_;
	my $plugin_class = ref $plugin;
	$self->trace('Handle request matches:',$plugin_class,"'".$request->query_raw."'",@args);
	unless ($self->allow_duplicate) {
		if (grep { $_ eq $plugin_class } @{$request->seen_plugins}) {
			$self->trace("The request already saw",$plugin_class);
			return ();
		}
	}
	push @{$request->seen_plugins}, $plugin_class;
	my @results = $plugin->handle_request_matches($request, @args);
	$self->trace("Got",scalar @results,"results");
	return @results;
}

around request => sub {
	my $orig = shift;
	my ( $self, $request ) = @_;
	$self->trace( "Query raw:", "'".$request->query_raw."'" );
	my @results = $orig->(@_);
	$self->trace( "Query", "'".$request->query_raw."'", "produced", scalar @results, "results" );
	return @results;
};

1;

__END__