File Coverage

blib/lib/DBIx/Connector/Driver.pm

Criterion	Covered	Total	%
statement	47	51	92.1
branch	6	8	75.0
condition	4	6	66.6
subroutine	18	21	85.7
pod	8	8	100.0
total	83	94	88.3

use strict; use warnings;

package DBIx::Connector::Driver;

our $VERSION = '0.60';

DRIVERS: {
    my %DRIVERS;

    sub new {
        my ($class, $driver) = @_;
        return $DRIVERS{$driver} ||= do {
            my $subclass = __PACKAGE__ . "::$driver";
            ( my $path = $subclass ) =~ s!::!/!g;
            local $@;
            my $ok = eval "require $subclass";
            die $@ unless $ok or $@ =~ /^Can't locate $path\.pm in \@INC \(/;
            bless { driver => $driver } => ( $ok ? $subclass : $class );
        };
    }
}

sub _connect {
    my ($self, $dbh, $dsn, $username, $password, $attrs) = @_;
    $dbh;
}

sub ping {
    my ($self, $dbh) = @_;
    $dbh->ping;
}

sub begin_work {
    my ($self, $dbh) = @_;
    $dbh->begin_work;
}

sub commit {
    my ($self, $dbh) = @_;
    $dbh->commit;
}

sub rollback {
    my ($self, $dbh) = @_;
    $dbh->rollback;
}

sub _rollback {
    my ($self, $dbh, $err) = @_;
    local $@;
    eval { $dbh->rollback };
    return $@ ? DBIx::Connector::TxnRollbackError->new(
        error          => $err,
        rollback_error => $@,
    ) : $err;
}

sub _rollback_and_release {
    my ($self, $dbh, $name, $err) = @_;
    local $@;
    eval {
        $self->rollback_to($dbh, $name);
        $self->release($dbh, $name);
    };
    return $@ ? DBIx::Connector::SvpRollbackError->new(
        error          => $err,
        rollback_error => $@,
    ) : $err;
}

sub savepoint {
    my ($self, $dbh, $name) = @_;
}

sub release {
    my ($self, $dbh, $name) = @_;
}

sub rollback_to {
    my ($self, $dbh, $name) = @_;
}

ROLLBACKERR: {
    package DBIx::Connector::RollbackError;
    our $VERSION = '0.58';
    # an exception is always true
    use overload bool => sub {1}, '""' => 'as_string', fallback => 1;

    sub new       { my $c = shift; bless {@_} => $c; }
    sub error     { shift->{error} }
    sub rollback_error { shift->{rollback_error} }
    sub as_string {
        my $self = shift;
        my $label = $self->_label;
        return "$label aborted: " . $self->error
            . "$label rollback failed: " . $self->rollback_error;
    }

    package DBIx::Connector::TxnRollbackError;
    our $VERSION = '0.58';
    our @ISA = qw( DBIx::Connector::RollbackError );
    sub _label    { 'Transaction' }

    package DBIx::Connector::SvpRollbackError;
    our $VERSION = '0.58';
    our @ISA = qw( DBIx::Connector::RollbackError );
    sub _label    { 'Savepoint' }
}

1;

__END__