File Coverage

blib/lib/Crypt/RIPEMD160/MAC.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	3	4	75.0
condition			n/a
subroutine	11	11	100.0
pod	6	6	100.0
total	65	66	98.4

package Crypt::RIPEMD160::MAC;

use Crypt::RIPEMD160 0.03;

use strict;
use warnings;
use Carp;

our $VERSION = '0.13';

sub new {
    my($pkg, $key) = @_;

    # Hash long keys per RFC 2104
    if (length($key) > 64) {
	$key = Crypt::RIPEMD160->hash($key);
    }

    my $k_ipad = chr(0x36) x 64;
    my $k_opad = chr(0x5c) x 64;
    $k_ipad ^= $key;
    $k_opad ^= $key;

    my $self = {
	'key' => $key,
	'hash' => Crypt::RIPEMD160->new,
	'k_ipad' => $k_ipad,
	'k_opad' => $k_opad,
	};

    bless $self, $pkg;

    $self->{'hash'}->add($self->{'k_ipad'});

    return $self;
}

sub reset {
    my($self) = @_;

    $self->{'hash'}->reset();
    $self->{'hash'}->add($self->{'k_ipad'});

    return $self;
}

sub add {
    my($self, @data) = @_;

    $self->{'hash'}->add(@data);

    return $self;
}

sub addfile
{
    my ($self, $handle) = @_;

    binmode($handle);
    $self->{'hash'}->addfile($handle);

    return $self;
}

sub DESTROY {
    my($self) = @_;

    # Best-effort zeroing of key material in Perl scalars.
    # Not as reliable as C-level secure_memzero (Perl may keep
    # copies via COW or realloc), but better than leaving keys
    # in memory until GC reclaims the storage.
    for my $field (qw(key k_ipad k_opad)) {
        if (defined $self->{$field}) {
            $self->{$field} = "\x00" x length($self->{$field});
            $self->{$field} = '';
        }
    }
}

sub mac {
    my($self) = @_;

    my($inner) = $self->{'hash'}->digest();

    return Crypt::RIPEMD160->hash($self->{'k_opad'}.$inner);
}

sub hexmac {
    my($self) = @_;

    my($inner) = $self->{'hash'}->digest();

    return Crypt::RIPEMD160->hexhash($self->{'k_opad'}.$inner);
}

1;
__END__