File Coverage

blib/lib/Crypt/Passphrase/Bcrypt.pm

Criterion	Covered	Total	%
statement	39	40	97.5
branch	9	14	64.2
condition	9	14	64.2
subroutine	10	11	90.9
pod	4	6	66.6
total	71	85	83.5

package Crypt::Passphrase::Bcrypt;
$Crypt::Passphrase::Bcrypt::VERSION = '0.009';
use strict;
use warnings;

use Crypt::Passphrase 0.010 -encoder;

use Carp qw/croak carp/;
use Crypt::Bcrypt 0.011 qw/bcrypt bcrypt_prehashed bcrypt_check_prehashed bcrypt_needs_rehash bcrypt_supported_prehashes/;

my %supported_prehash = map { $_ => 1 } bcrypt_supported_prehashes();

sub ignore {
}

my %checkers = (
	ignore => \&ignore,
	warn   => \&carp,
	die    => \&croak,
);

sub new {
	my ($class, %args) = @_;
	my $subtype = $args{subtype} // '2b';
	croak "Unknown subtype $subtype" unless $subtype =~ / \A 2 [abxy] \z /x;
	my $hash = $args{hash} // '';
	croak 'Invalid hash' if length $args{hash} and not $supported_prehash{ $args{hash} };

	my $check = $args{length_check} // 'die';
	my $checker = ref $check ? $check : $checkers{$check};
	croak "Invalid length check value $check" if not defined $checker;

	return bless {
		cost    => $args{cost} // 14,
		subtype => $subtype,
		hash    => $hash,
		checker => $checker,
	}, $class;
}

sub hash_password {
	my ($self, $password) = @_;

	if (!$self->{hash} && $self->{checker} != \&ignore) {
		my $length = length $password;
		if ($length > 72) {
			$self->{checker}->("Password is only allowed to be 72 characters, got $length characters");
		}
		if ($password =~ /\0/) {
			$self->{checker}->("Password is not allowed to contain null characters");
		}
	}

	my $salt = $self->random_bytes(16);
	return bcrypt_prehashed($password, $self->{subtype}, $self->{cost}, $salt, $self->{hash});
}

sub needs_rehash {
	my ($self, $hash) = @_;
	return bcrypt_needs_rehash($hash, @{$self}{qw/subtype cost hash/});
}

sub crypt_subtypes {
	return (qw/2a 2b 2x 2y/, map { "bcrypt-$_" } bcrypt_supported_prehashes());
}

sub verify_password {
	my ($class, $password, $hash) = @_;
	return bcrypt_check_prehashed($password, $hash);
}

1;

#ABSTRACT: A bcrypt encoder for Crypt::Passphrase

__END__