File Coverage

blib/lib/Crypt/OpenPGP/Digest.pm

Criterion	Covered	Total	%
statement	115	123	93.5
branch	5	12	41.6
condition	2	3	66.6
subroutine	37	39	94.8
pod	4	6	66.6
total	163	183	89.0

package Crypt::OpenPGP::Digest;
use strict;
use warnings;

our $VERSION = '1.19'; # VERSION

use Crypt::OpenPGP::ErrorHandler;
use base qw( Crypt::OpenPGP::ErrorHandler );

our %ALG = (
    1 => 'MD5',
    2 => 'SHA1',
    3 => 'RIPEMD160',
    8 => 'SHA256',
    9 => 'SHA384',
    10 => 'SHA512',
    11 => 'SHA224',
);
our %ALG_BY_NAME = map { $ALG{$_} => $_ } keys %ALG;

sub new {
    my $class = shift;
    my $alg = shift;
    $alg = $ALG{$alg} || $alg;
    return $class->error("Unsupported digest algorithm '$alg'")
        unless $alg =~ /^\D/;
    my $pkg = join '::', $class, $alg;
    my $dig = bless { __alg => $alg,
                      __alg_id => $ALG_BY_NAME{$alg} }, $pkg;
    $dig->init(@_);
}

sub init { $_[0] }
sub hash { $_[0]->{md}->($_[1]) }

sub alg {
    return $_[0]->{__alg} if ref($_[0]);
    $ALG{$_[1]} || $_[1];
}

sub alg_id {
    return $_[0]->{__alg_id} if ref($_[0]);
    $ALG_BY_NAME{$_[1]} || $_[1];
}

sub supported {
    my $class = shift;
    my %s;
    for my $did (keys %ALG) {
        my $digest = $class->new($did);
        $s{$did} = $digest->alg if $digest;
    }
    \%s;
}

package Crypt::OpenPGP::Digest::MD5;
use strict;
use warnings;

use base qw( Crypt::OpenPGP::Digest );

sub init {
    my $dig = shift;
    require Digest::MD5;
    $dig->{md} = \&Digest::MD5::md5;
    $dig;
}

package Crypt::OpenPGP::Digest::SHA1;
use strict;
use warnings;

use base qw( Crypt::OpenPGP::Digest );

sub init {
    my $dig = shift;
    require Digest::SHA;
    $dig->{md} = \&Digest::SHA::sha1;
    $dig;
}

package Crypt::OpenPGP::Digest::RIPEMD160;
use strict;
use warnings;

use base qw( Crypt::OpenPGP::Digest );

sub init {
    my $dig = shift;
    require Crypt::RIPEMD160;
    $dig->{md} = sub { Crypt::RIPEMD160->hash($_[0]) };
    $dig;
}

package Crypt::OpenPGP::Digest::SHA224;
use strict;
use warnings;

use base qw( Crypt::OpenPGP::Digest );

sub init {
    my $dig = shift;
    require Digest::SHA;
    $dig->{md} = \&Digest::SHA::sha224;
    $dig;
}

package Crypt::OpenPGP::Digest::SHA256;
use strict;
use warnings;

use base qw( Crypt::OpenPGP::Digest );

sub init {
    my $dig = shift;
    require Digest::SHA;
    $dig->{md} = \&Digest::SHA::sha256;
    $dig;
}

package Crypt::OpenPGP::Digest::SHA384;
use strict;
use warnings;

use base qw( Crypt::OpenPGP::Digest );

sub init {
    my $dig = shift;
    require Digest::SHA;
    $dig->{md} = \&Digest::SHA::sha384;
    $dig;
}

package Crypt::OpenPGP::Digest::SHA512;
use strict;
use warnings;

use base qw( Crypt::OpenPGP::Digest );

sub init {
    my $dig = shift;
    require Digest::SHA;
    $dig->{md} = \&Digest::SHA::sha512;
    $dig;
}


1;
__END__