File Coverage

lib/Config/Proxy/Node.pm

Criterion	Covered	Total	%
statement	78	92	84.7
branch	21	38	55.2
condition	3	5	60.0
subroutine	19	21	90.4
pod	14	15	93.3
total	135	171	78.9

package Config::Proxy::Node;
use strict;
use warnings;
use Carp;
use Config::Proxy::Iterator;

sub new {
    my $class = shift;
    local %_ = @_;
    bless {
	_kw => $_{kw},
	_argv => $_{argv} // [],
	_orig => $_{orig},
	_locus => $_{locus},
	_parent => $_{parent},
	_index => -1
    }, $class;
}

my @ATTRIBUTES = qw(kw orig locus parent index);

{
    no strict 'refs';
    foreach my $attribute (@ATTRIBUTES) {
	*{ __PACKAGE__ . '::' . $attribute } = sub {
	    my $self = shift;
	    if (defined(my $val = shift)) {
		croak "too many arguments" if @_;
		$self->{'_'.$attribute} = $val;
	    }
	    return $self->{'_'.$attribute};
	}
    }
}

sub argv {
    my $self = shift;
    if (my $val = shift) {
	croak "too many arguments" if @_;
	$self->{_argv} = $val;
	delete $self->{_orig};
    }
    return @{$self->{_argv}};
}

sub arg {
    my $self = shift;
    my $n = shift;
    if (my $val = shift) {
	croak "too many arguments" if @_;
	$self->{_argv}[$n] = $val;
    }
    return $self->{_argv}[$n];
}

sub drop {
    my $self = shift;
    $self->parent->delete_node($self->index);
}

sub iterator {
    return new Config::Proxy::Iterator(@_);
}

sub write {
    my $self = shift;
    my $file = shift;
    my $fh;

    if (!defined($file)) {
	$file = \*STDOUT
    }
    if (ref($file) eq 'GLOB') {
	$fh = $file;
    } else {
	open($fh, '>', $file) or croak "can't open $file: $!";
    }

    $self->format($fh, @_) if $self->is_section && !$self->is_root;

    my $itr = $self->iterator(inorder => 1);

    while (defined(my $node = $itr->next)) {
	$node->format($fh, @_);
    }

    close $fh unless ref($file) eq 'GLOB';
}

sub format {
    my ($self, $fh, %opts) = @_;

    my $s = $self->as_string;
    if ($opts{indent}) {
	if ($self->is_comment) {
	    if ($opts{reindent_comments}) {
		my $indent = ' ' x ($opts{indent} * $self->depth);
		$s =~ s/^\s+//;
		$s = $indent . $s;
	    }
	} else {
	    my $indent = ' ' x ($opts{indent} * $self->depth);
	    if ($opts{tabstop}) {
		$s = $indent . $self->kw;
		for (my $i = 0; my $arg = $self->arg($i); $i++) {
		    my $off = 1;
		    if ($i < @{$opts{tabstop}}) {
			if (($off = $opts{tabstop}[$i] - length($s)) <= 0) {
			    $off = 1;
			}
		    }
		    $s .= (' ' x $off) . $arg;
		}
	    } else {
		$s =~ s/^\s+//;
		$s = $indent . $s;
	    }
	}
    }
    print $fh $s,"\n";
}

sub depth {
    my $self = shift;
    my $n = 0;
    while ($self = $self->parent) {
	$n++;
    }
    return $n - 1;
}

sub root {
    my $self = shift;
    while ($self->parent()) {
	$self = $self->parent();
    }
    return $self;
}

sub as_string {
    my $self = shift;
    if (defined(my $v = $self->orig)) {
	return $v;
    }
    return '' unless $self->kw;
    return $self->orig(join(' ', ($self->kw, $self->argv())));
}

# use overload
#     '""' => sub { shift->as_string };

sub is_root { 0 }
sub is_section { 0 }
sub is_statement { 0 }
sub is_empty { 0 }
sub is_comment { 0 }

1;
__END__