File Coverage

lib/Config/Proxy/Impl/haproxy.pm

Criterion	Covered	Total	%
statement	65	67	97.0
branch	7	8	87.5
condition	1	2	50.0
subroutine	15	16	93.7
pod	0	4	0.0
total	88	97	90.7

package Config::Proxy::Impl::haproxy;
use 5.010;
use strict;
use warnings;
use parent 'Config::Proxy::Base';
use Text::Locus;
use Config::Proxy::Node::Root;
use Config::Proxy::Node::Section;
use Config::Proxy::Node::Statement;
use Config::Proxy::Node::Comment;
use Config::Proxy::Node::Empty;
use Text::ParseWords;
use Carp;

our $VERSION = '1.0';

my %sections = (
    global => 1,
    defaults => 1,
    frontend => 1,
    backend => 1,
    resolvers => 1
);

sub new {
    my $class = shift;
    return $class->SUPER::new(shift // '/etc/haproxy/haproxy.cfg', 'haproxy -c -f');
}

sub parse {
    my $self = shift;

    open(my $fh, '<', $self->filename)
	or croak "can't open ".$self->filename.": $!";
    my $line = 0;
    $self->reset();
    my $cur = $self->tree;
    while (<$fh>) {
	my $locus = new Text::Locus($self->filename, ++$line);
	chomp;
	my $orig = $_;
	s/^\s+//;
	s/\s+$//;

	if ($_ eq "") {
	    $cur->append_node(
		new Config::Proxy::Node::Empty(orig => $orig,
					       locus => $locus));
	    next;
	}

	if (/^#.*/) {
	    $cur->append_node(
		new Config::Proxy::Node::Comment(orig => $orig,
						 locus => $locus));
	    next;
	}

	my @words = parse_line('\s+', 1, $_);
	my $kw = shift @words;
	if ($sections{$kw}) {
	    my $section =
		new Config::Proxy::Node::Section(kw => $kw,
						 argv => \@words,
						 orig => $orig,
						 locus => $locus);
	    $self->tree->append_node($section);
	    $cur = $section;
	} else {
	    $cur->append_node(
		new Config::Proxy::Node::Statement(kw => $kw,
						   argv => \@words,
						   orig => $orig,
						   locus => $locus));
	}
    }
    close $fh;
    return $self;
}

sub declare_section {
    my ($class, $name) = @_;
    $sections{$name} = 1;
}

sub undeclare_section {
    my ($class, $name) = @_;
    $sections{$name} = 0;
}

1;
__END__