File Coverage

blib/lib/Class/Method/Cache/FastMmap.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch	4	4	100.0
condition	6	8	75.0
subroutine	9	9	100.0
pod	1	1	100.0
total	54	56	96.4

package Class::Method::Cache::FastMmap;

# ABSTRACT: Cache method results using Cache::FastMmap

use v5.10.1;

use strict;
use warnings;

use base 'Exporter::Tiny';

use Cache::FastMmap;
use Class::Method::Modifiers qw/ install_modifier /;
use Object::Signature ();

our $VERSION = 'v0.3.2';

our @EXPORT    = qw/ cache /;
our @EXPORT_OK = @EXPORT;


sub cache {
    my ( $method, %options ) = @_;

    my $target = caller;

    my $global = delete $options{cache};
    my $prefix = delete $options{prefix}
      // ( $global ? "${target}::${method}::" : '' );
    my $key_cb = delete $options{key_cb} // \&Object::Signature::signature;

    install_modifier $target, 'around', $method, sub {
        my $next = shift;
        my $self = shift;

        state $cache = $global // Cache::FastMmap->new(%options);

        my $key = $prefix . $key_cb->( [ $self, @_ ] );
        my $value = $cache->get($key);
        unless ( defined $value ) {
            $cache->set( $key, $value = $self->$next(@_) );
        }
        return $value;
    };

}


1;

__END__