File Coverage

blib/lib/Cisco/SNMP/ARP.pm

Criterion	Covered	Total	%
statement	16	66	24.2
branch	0	26	0.0
condition	0	3	0.0
subroutine	6	10	60.0
pod	3	3	100.0
total	25	108	23.1

package Cisco::SNMP::ARP;

##################################################
# AUTHOR = Michael Vincent
# www.VinsWorld.com
##################################################

use strict;
use warnings;

use Net::SNMP qw(:asn1);
use Cisco::SNMP;

our $VERSION = $Cisco::SNMP::VERSION;

our @ISA = qw(Cisco::SNMP);

##################################################
# Start Public Module
##################################################

sub _arpOID {
    return '.1.3.6.1.2.1.4.22.1';
}

sub arpOIDs {
    return qw(IfIndex PhysAddress NetAddress Type);
}

sub arp_clear {
    my $self = shift;
    my ( $idx, $ip ) = @_;

    if ( not defined $idx ) {
        $Cisco::SNMP::LASTERROR = "ifIndex required";
        return undef;
    } elsif ( $idx !~ /^\d+$/ ) {
        $Cisco::SNMP::LASTERROR = "Invalid ifIndex `$idx'";
        return undef;
    }
    if ( not defined $ip ) {
        $Cisco::SNMP::LASTERROR = "IP address required";
        return undef;
    } elsif ( $ip !~ /^\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}$/ ) {
        $Cisco::SNMP::LASTERROR = "Invalid IP Address `$ip'";
        return undef;
    }

    my $s = $self->session;
    my $r = $s->set_request( _arpOID() . ".4.$idx.$ip", INTEGER, 2 );
    if ( not defined $r ) {
        $Cisco::SNMP::LASTERROR = $s->error;
        return undef;
    }
    return $r->{_arpOID() . ".4.$idx.$ip"};
}

sub arp_info {
    my $self = shift;
    my $class = ref($self) || $self;

    my $session = $self->{_SESSION_};

    my %ret;
    my @ARPKEYS = arpOIDs();
    for my $oid ( 0 .. $#ARPKEYS ) {
        $ret{$ARPKEYS[$oid]} = Cisco::SNMP::_snmpwalk( $session,
            _arpOID() . '.' . ( $oid + 1 ) );
        if ( not defined $ret{$ARPKEYS[$oid]} ) {
            $Cisco::SNMP::LASTERROR = "Cannot get ARP `$ARPKEYS[$oid]' info";
            return undef;
        }
    }

    my %ArpType = (
        1 => 'OTHER',
        2 => 'INVALID',
        3 => 'DYNAMIC',
        4 => 'STATIC'
    );
    my @ArpInfo;
    for my $arp ( 0 .. $#{$ret{$ARPKEYS[0]}} ) {
        my %ArpInfoHash;
        for ( 0 .. $#ARPKEYS ) {
            if ( $_ == 1 ) {
                $ArpInfoHash{$ARPKEYS[$_]}
                  = ( $ret{$ARPKEYS[$_]}->[$arp] =~ /^\0/ )
                  ? unpack( 'H12', $ret{$ARPKEYS[$_]}->[$arp] )
                  : ( ( $ret{$ARPKEYS[$_]}->[$arp] =~ /^0x/ )
                    ? substr( $ret{$ARPKEYS[$_]}->[$arp], 2 )
                    : $ret{$ARPKEYS[$_]}->[$arp] );
            } elsif ( $_ == 3 ) {
                $ArpInfoHash{$ARPKEYS[$_]}
                  = exists( $ArpType{$ret{$ARPKEYS[$_]}->[$arp]} )
                  ? $ArpType{$ret{$ARPKEYS[$_]}->[$arp]}
                  : $ret{$ARPKEYS[$_]}->[$arp];
            } else {
                $ArpInfoHash{$ARPKEYS[$_]} = $ret{$ARPKEYS[$_]}->[$arp];
            }
        }
        push @ArpInfo, \%ArpInfoHash;
    }
    return bless \@ArpInfo, $class;
}

for ( arpOIDs() ) {
    Cisco::SNMP::_mk_accessors_array_1( 'arp', $_ );
}

no strict 'refs';

# get_ direct
my @OIDS = arpOIDs();
for my $o ( 0 .. $#OIDS ) {
    *{"get_arp" . $OIDS[$o]} = sub {
        my $self = shift;
        my ( $val1, $val2 ) = @_;

        if ( not defined $val1 ) { $val1 = 1 }
        if ( not defined $val2 ) { $val2 = '1.1.1.1' }
        my $s = $self->session;
        my $r = $s->get_request( varbindlist =>
              [_arpOID() . '.' . ( $o + 1 ) . '.' . "$val1.$val2"] );
        return $r->{_arpOID() . '.' . ( $o + 1 ) . '.' . "$val1.$val2"};
      }
}

##################################################
# End Public Module
##################################################

1;

__END__