File Coverage

lib/CSS/SpriteBuilder/ImageDriver/GD.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package CSS::SpriteBuilder::ImageDriver::GD;

=head1 NAME

CSS::SpriteBuilder::ImageDriver::GD - Class for image manipulation using GD module.

=cut

use warnings;
use strict;
use GD;
use base 'CSS::SpriteBuilder::ImageDriver::Common';

our %COLOR_MAP = map {
    chomp;
    my ($name, @rgb) = split /\s+/;
    $name = [ map { hex $_ } @rgb ];
} ;

# Use truecolor by default
GD::Image->trueColor(1);

sub driver         { 'GD'                                            }
sub width          { $_[0]->{_image} ? $_[0]->{_image}->width()  : 0 }
sub height         { $_[0]->{_image} ? $_[0]->{_image}->height() : 0 }

sub reset {
    my ($self, $image) = @_;

    $self->{_image} = $image ? $image->{_image}->clone() : undef;

    return;
}

sub read {
    my ($self, $filename) = @_;

    $self->{_image} = GD::Image->new($filename)
        or die "Failed to read image from '$filename' due: $!";

    $self->{_image}->alphaBlending(0);
    $self->{_image}->saveAlpha(1);

    return;
}

sub write {
    my ($self, $filename) = @_;

    return unless $self->{_image};

    if ($filename =~ /\.(png|jpg|gif)$/i) {
        my $ext = lc $1;
        my $data;
        if ($ext eq 'png') {
            $data = $self->{_image}->png();
        }
        elsif ($ext eq 'jpg') {
            $data = $self->{_image}->jpeg( $self->{_quality} );
        }
        else {
            $data = $self->{_image}->gif();
        }
        die "Failed to write image due: $!" unless $data;

        open(my $fh, '>', $filename) or die "Failed to open file '$filename' due: $!";
        binmode $fh;
        print $fh $data;
        close $fh or die "Failed to close file '$filename' due: $!";
    }
    else {
        die "Unknown extension of the file '$filename'";
    }

    return;
}

sub set_transparent_color {
    my ($self, $color) = @_;

    return unless $self->{_image};

    my $rgb   = $COLOR_MAP{ lc $color } or die "Unknown color '$color'";
    my $index = $self->{_image}->colorClosest(@$rgb);
    $self->{_image}->transparent($index);

    return;
}

sub extent {
    my ($self, $width, $height) = @_;

    my $old_image = $self->{_image};
    my $new_image = GD::Image->new($width, $height, 1);

    $new_image->alphaBlending(0);
    $new_image->saveAlpha(1);
    $new_image->copy( $old_image, 0, 0, 0, 0, $old_image->width(), $old_image->height() )
        if $old_image;

    $self->{_image} = $new_image;

    return;
}

sub composite {
    my ($self, $image, $x, $y) = @_;

    $self->{_image}->copy( $image->{_image}, $x, $y, 0, 0, $image->width(), $image->height() );

    return;
}

1;

__DATA__