File Coverage

blib/lib/CPAN/02Packages/Search.pm

Criterion	Covered	Total	%
statement	17	58	29.3
branch	0	18	0.0
condition	0	3	0.0
subroutine	6	10	60.0
pod	0	2	0.0
total	23	91	25.2

package CPAN::02Packages::Search v1.0.0;
use v5.24;
use warnings;
use experimental qw(lexical_subs signatures);

our $TRIAL = 0;

use Search::Dict ();
use Symbol ();
use Tie::Handle::SkipHeader;


sub new ($class, %argv) {
    my $fh = $argv{fh};
    if (!$fh) {
        my $file = $argv{file};
        my $skip_header = exists $argv{skip_header} ? $argv{skip_header} : 1;
        $fh = $class->_open($file, $skip_header);
    }
    bless { fh => $fh }, $class;
}

sub _open ($class, $file, $skip_header) {
    if ($skip_header) {
        my $fh = Symbol::gensym;
        tie *$fh, 'Tie::Handle::SkipHeader', '<', $file or die "$!: $file\n";
        return $fh;
    }
    open my $fh, "<", $file or die "$!: $file\n";
    $fh;
}

sub search ($self, $package) {
    my $fh = $self->{fh};
    seek $fh, 0, 0;
    my $pos = Search::Dict::look $fh, $package, { xfrm => \&_xform_package, fold => 1 };
    return if $pos == -1 || eof $fh;
    while (my $line = <$fh>) {
        last if $line !~ /\A\Q$package\E\s+/i;
        chomp $line;
        my ($_package, $version, $path) = split /\s+/, $line, 4;
        if ($package eq $_package) {
            $version = undef if $version eq 'undef';
            return { version => $version, path => $path };
        }
    }
    return;
}

sub _xform_package ($line) { (split " ", $line, 2)[0] }

1;
__END__