File Coverage

blib/lib/Business/CPI/Gateway/Base.pm

Criterion	Covered	Total	%
statement	41	65	63.0
branch	6	12	50.0
condition	0	2	0.0
subroutine	9	17	52.9
pod	8	8	100.0
total	64	104	61.5

package Business::CPI::Gateway::Base;
# ABSTRACT: Father of all gateways
use Moo;
use Locale::Currency ();
use Data::Dumper;
use Carp qw/croak/;
use Business::CPI::Util::Types qw/UserAgent HTTPResponse/;
use Types::Standard qw/Maybe/;
use LWP::UserAgent;

with 'Business::CPI::Role::Gateway::Base';

our $VERSION = '0.922'; # VERSION

has receiver_id => (
    is => 'ro',
);

has checkout_url => (
    is => 'rw',
);

has checkout_with_token => (
    is => 'ro',
    default => sub { 0 },
);

has currency => (
    isa => sub {
        my $curr = uc($_[0]);

        for (Locale::Currency::all_currency_codes()) {
            return 1 if $curr eq uc($_);
        }

        die "Must be a valid currency code";
    },
    coerce => sub { uc $_[0] },
    is => 'ro',
);

has user_agent => (
    is => 'rwp',
    isa => UserAgent,
    lazy => 1,
    builder => '_build_user_agent',
);

has most_recent_request => (
    is => 'rwp',
    isa => Maybe[HTTPResponse],
);

has error => ( is => 'rwp' );

sub new_account {
    my ($self, $account) = @_;

    return $self->account_class->new(
        _gateway => $self,
        %$account
    );
}

sub new_cart {
    my ( $self, $info ) = @_;

    if ($self->log->is_debug) {
        $self->log->debug("Building a cart with: " . Dumper($info));
    }

    my @items     = @{ delete $info->{items}     || [] };
    my @receivers = @{ delete $info->{receivers} || [] };

    my $buyer_class = $self->buyer_class;
    my $cart_class  = $self->cart_class;

    # We might be using a more generic Account class
    if ($buyer_class->does('Business::CPI::Role::Account')) {
        $info->{buyer}{_gateway} = $self;
    }

    $self->log->debug(
        "Loaded buyer class $buyer_class and cart class $cart_class."
    );

    my $buyer = $buyer_class->new( delete $info->{buyer} );

    $self->log->info("Built cart for buyer " . $buyer->email);

    my $cart = $cart_class->new(
        _gateway => $self,
        buyer    => $buyer,
        %$info,
    );

    for (@items) {
        $cart->add_item($_);
    }

    for (@receivers) {
        $cart->add_receiver($_);
    }

    return $cart;
}

sub map_object {
    my ($self, $map, $obj) = @_;

    my @result;

    while (my ($bcpi_key, $gtw_key) = each %$map) {
        my $value = $obj->$bcpi_key;
        next unless $value;

        my $name = $gtw_key;

        if (ref $gtw_key) {
            $name  = $gtw_key->{name};
            $value = $gtw_key->{coerce}->($name);
        }

        push @result, ( $name, $value );
    }

    return @result;
}

sub get_notification_details { shift->_unimplemented }

sub query_transactions { shift->_unimplemented }

sub get_transaction_details { shift->_unimplemented }

sub notify { shift->_unimplemented }

sub get_checkout_code { shift->_unimplemented }

sub _unimplemented {
    my $self = shift;
    die "Not implemented.";
}

sub _build_user_agent {
    my ($self) = @_;

    my $class_name = ref $self;
    my $version = eval { $self->VERSION } || 'devel';

    return LWP::UserAgent->new(agent => "$class_name/$version");
}

around BUILDARGS => sub {
    my $orig = shift;
    my $self = shift;
    my $args = $self->$orig(@_);

    if ($args->{receiver_email}) {
        croak 'receiver_email attribute has been removed - use receiver_id instead';
    }

    return $args;
};

1;

__END__