File Coverage

blib/lib/Blockchain/Ethereum/Utils.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	8	8	100.0
condition	3	3	100.0
subroutine	14	14	100.0
pod	2	2	100.0
total	64	64	100.0

package Blockchain::Ethereum::Utils;

use v5.26;
use strict;
use warnings;

# ABSTRACT: Utility functions for Ethereum operations
our $AUTHORITY = 'cpan:REFECO';    # AUTHORITY
our $VERSION   = '0.021';          # VERSION

use Carp;
use Math::BigInt;
use Math::BigFloat;
use Scalar::Util qw(looks_like_number);
use Exporter 'import';

our @EXPORT = qw(
    parse_units format_units
    WEI KWEI MWEI GWEI SZABO FINNEY ETHER ETH
);

use constant {
    WEI    => 0,
    KWEI   => 3,
    MWEI   => 6,
    GWEI   => 9,
    SZABO  => 12,
    FINNEY => 15,
    ETHER  => 18,
    ETH    => 18,    # alias for ether
};

my %ETHEREUM_UNITS = (
    'wei'    => WEI,
    'kwei'   => KWEI,
    'mwei'   => MWEI,
    'gwei'   => GWEI,
    'szabo'  => SZABO,
    'finney' => FINNEY,
    'ether'  => ETHER,
    'eth'    => ETH,
);

sub _process_units {
    my ($value, $unit, $processor) = @_;

    croak "Invalid number format" unless defined $value && looks_like_number($value);
    croak "Unknown unit"          unless defined $unit;

    my $decimals =
          $unit =~ /^\d+$/                  ? $unit
        : exists $ETHEREUM_UNITS{lc($unit)} ? $ETHEREUM_UNITS{lc($unit)}
        :                                     croak "Unknown unit";

    return $processor->(Math::BigFloat->new($value), Math::BigInt->new(10)->bpow($decimals));
}

sub parse_units {
    my ($value, $unit) = @_;
    return _process_units($value, $unit, sub { Math::BigInt->new($_[0]->bmul($_[1]))->bstr() });
}

sub format_units {
    my ($value, $unit) = @_;
    return _process_units($value, $unit, sub { $_[0]->bdiv($_[1])->bstr() });
}

1;

__END__