File Coverage

blib/lib/Blockchain/Ethereum/Transaction.pm

Criterion	Covered	Total	%
statement	64	65	98.4
branch	12	14	85.7
condition	14	22	63.6
subroutine	26	27	96.3
pod	3	17	17.6
total	119	145	82.0

package Blockchain::Ethereum::Transaction;

use v5.26;
use strict;
use warnings;

# ABSTRACT: Ethereum transaction abstraction
our $AUTHORITY = 'cpan:REFECO';    # AUTHORITY
our $VERSION   = '0.021';          # VERSION

use Carp;
use Crypt::Digest::Keccak256 qw(keccak256);
use Scalar::Util             qw(blessed looks_like_number);
use Math::BigInt;

use Blockchain::Ethereum::RLP;

sub new {
    my ($class, %args) = @_;

    my $self = bless {}, $class;

    foreach (qw(chain_id nonce gas_limit to value data v r s)) {
        $self->{$_} = $args{$_} if exists $args{$_};
    }

    return $self;
}

sub rlp {
    my $self = shift;

    return $self->{rlp} //= Blockchain::Ethereum::RLP->new;
}

sub chain_id {
    return shift->{chain_id};
}

sub nonce {
    return shift->{nonce};
}

sub gas_limit {
    return shift->{gas_limit};
}

sub to {
    return shift->{to} // '';
}

sub value {
    return shift->{value} // '0x0';
}

sub data {
    return shift->{data} // '';
}

sub v {
    return shift->{v};
}

sub set_v {
    my ($self, $v) = @_;
    $self->{v} = $v;
}

sub r {
    return shift->{r};
}

sub set_r {
    my ($self, $r) = @_;
    $self->{r} = $r;
}

sub s {
    my $self = shift;
    return $self->{s};
}

sub set_s {
    my ($self, $s) = @_;
    $self->{s} = $s;
}

sub serialize {
    croak "serialize method not implemented";
}

sub hash {
    my $self = shift;

    return keccak256($self->serialize);
}

# Hex conversion
sub _normalize_params {
    my ($self, $params) = @_;

    return [
        map {
            !defined $_
                ? $_                                                                                                   # undefined
                : blessed $_ && $_->isa('Math::BigInt') ? $_->as_hex                                                   # BigInt
                : /^0x/i                                ? $_                                                           # hex string
                : looks_like_number($_) && $_ == int($_)                            ? Math::BigInt->new($_)->as_hex    # integer/numeric string
                : blessed $_            && $_->isa('Blockchain::Ethereum::Address') ? $_->to_string                    # Ethereum Address object
                : $_                                                                                                   # anything else
        } @$params
    ];
}

sub _encode_access_list {
    my $self = shift;

    my $access_list = $self->access_list();

    # If no access list, return empty array
    return [] unless @$access_list;

    my @encoded_list;

    for my $entry (@$access_list) {
        my $address      = $entry->{address}      // '';
        my $storage_keys = $entry->{storage_keys} // [];

        push @encoded_list, [$address, $storage_keys];
    }

    return \@encoded_list;
}

sub generate_v {
    my ($self, $y_parity) = @_;

    # eip-1559 and eip-2930 uses y-parity directly as the v value
    my $v = sprintf("0x%x", $y_parity);
    $self->set_v($v);
    return $v;
}

1;

__END__