File Coverage

blib/lib/Blockchain/Ethereum/Transaction/EIP4844.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	3	4	75.0
condition	7	10	70.0
subroutine	12	12	100.0
pod	1	7	14.2
total	53	63	84.1

package Blockchain::Ethereum::Transaction::EIP4844;

use v5.26;
use strict;
use warnings;

# ABSTRACT: Ethereum Blob transaction abstraction (EIP-4844)
our $AUTHORITY = 'cpan:REFECO';    # AUTHORITY
our $VERSION   = '0.021';          # VERSION

use parent 'Blockchain::Ethereum::Transaction';

use constant TRANSACTION_PREFIX => pack("H*", '03');

sub new {
    my ($class, %args) = @_;
    my $self = $class->SUPER::new(%args);

    foreach (qw( max_priority_fee_per_gas max_fee_per_gas max_fee_per_blob_gas blob_versioned_hashes access_list )) {
        $self->{$_} = $args{$_} if exists $args{$_};
    }

    bless $self, $class;
    return $self;
}

sub max_fee_per_blob_gas {
    return shift->{max_fee_per_blob_gas};
}

sub max_priority_fee_per_gas {
    return shift->{max_priority_fee_per_gas};
}

sub max_fee_per_gas {
    return shift->{max_fee_per_gas};
}

sub blob_versioned_hashes {
    return shift->{blob_versioned_hashes} // [];
}

sub access_list {
    return shift->{access_list} // [];
}

sub serialize {
    my $self = shift;

    my @params = (
        $self->chain_id,            $self->nonce, $self->max_priority_fee_per_gas, $self->max_fee_per_gas,
        $self->gas_limit,           $self->to,    $self->value,                    $self->data,
        $self->_encode_access_list, $self->max_fee_per_blob_gas, $self->blob_versioned_hashes,
    );

    @params = $self->_normalize_params(\@params)->@*;

    push(@params, $self->v, $self->r, $self->s)
        if $self->v && $self->r && $self->s;

    return TRANSACTION_PREFIX . $self->rlp->encode(\@params);
}

1;

__END__