File Coverage

blib/lib/Blockchain/Ethereum/Seed.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	12	16	75.0
condition			n/a
subroutine	13	13	100.0
pod	0	5	0.0
total	67	76	88.1

package Blockchain::Ethereum::Seed;

use v5.26;
use strict;
use warnings;

# ABSTRACT: Seed abstraction
our $AUTHORITY = 'cpan:REFECO';    # AUTHORITY
our $VERSION   = '0.021';          # VERSION

use Carp;
use Crypt::PRNG     qw(random_bytes);
use Bitcoin::Crypto qw(btc_extprv);

use Blockchain::Ethereum::Key;

sub new {
    my ($class, %params) = @_;

    my $self = bless {}, $class;
    foreach (qw(seed mnemonic salt)) {
        $self->{$_} = $params{$_} if exists $params{$_};
    }

    if ($self->seed) {
        $self->{hdw_handler} = btc_extprv->from_seed($self->seed);
    } elsif ($self->mnemonic) {
        $self->{hdw_handler} = btc_extprv->from_mnemonic($self->mnemonic, $self->salt);
    }

    unless ($self->_hdw_handler) {
        # if the seed is not given, generate a new one
        $self->{seed}        = random_bytes(64);
        $self->{hdw_handler} = btc_extprv->from_seed($self->seed);
    }

    return $self;
}

sub seed {
    shift->{seed};
}

sub mnemonic {
    shift->{mnemonic};
}

sub salt {
    shift->{salt};
}

sub _hdw_handler {
    shift->{hdw_handler};
}

sub derive_key {
    my ($self, $index, $account, $purpose, $coin_type, $change) = @_;

    $account   = 0  unless $account;
    $purpose   = 44 unless $purpose;
    $coin_type = 60 unless $coin_type;
    $change    = 0  unless $change;

    my $path = Bitcoin::Crypto::BIP44->new(
        index     => $index,
        purpose   => $purpose,
        coin_type => $coin_type,
        account   => $account,
        change    => $change,
    );

    return Blockchain::Ethereum::Key->new(private_key => $self->_hdw_handler->derive_key($path)->get_basic_key->to_serialized);
}

1;

__END__