File Coverage

blib/lib/Blockchain/Ethereum/Address.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	4	6	66.6
condition			n/a
subroutine	11	11	100.0
pod	2	4	50.0
total	56	60	93.3

package Blockchain::Ethereum::Address;

use v5.26;
use strict;
use warnings;

# ABSTRACT: Ethereum address abstraction
our $AUTHORITY = 'cpan:REFECO';    # AUTHORITY
our $VERSION   = '0.021';          # VERSION

use Carp;
use Crypt::Digest::Keccak256 qw(keccak256_hex);

sub new {
    my ($class, %params) = @_;

    my $address = $params{address};
    croak "Required param address not given" unless $address;

    my $self = bless {}, $class;
    $self->{address} = $address;
    $self->_checksum;

    return $self;
}

sub address {
    return shift->{address};
}

sub _checksum {
    my ($self) = shift;

    my $unprefixed = $self->no_prefix;

    croak 'Invalid address format' unless length($unprefixed) == 40;

    my @hashed_chars      = split //, keccak256_hex(lc $unprefixed);
    my @address_chars     = split //, $unprefixed;
    my $checksummed_chars = '';

    $checksummed_chars .= hex $hashed_chars[$_] >= 8 ? uc $address_chars[$_] : lc $address_chars[$_] for 0 .. length($unprefixed) - 1;

    $self->{address} = "0x$checksummed_chars";
    return $self;
}

sub no_prefix {
    my $self = shift;

    my $unprefixed = $self->address =~ s/^0x//r;
    return $unprefixed;
}

use overload
    fallback => 1,
    '""'     => \&to_string;

sub to_string {
    my $self = shift;
    return $self->address;
}

1;

__END__