File Coverage

blib/lib/Blockchain/Ethereum/ABI/Encoder.pm

Criterion	Covered	Total	%
statement	51	51	100.0
branch	6	8	75.0
condition	1	3	33.3
subroutine	14	14	100.0
pod	5	6	83.3
total	77	82	93.9

package Blockchain::Ethereum::ABI::Encoder;

use v5.26;
use strict;
use warnings;

# ABSTRACT: ABI utility for encoding ethereum contract arguments
our $AUTHORITY = 'cpan:REFECO';    # AUTHORITY
our $VERSION   = '0.021';          # VERSION

use Carp;
use Crypt::Digest::Keccak256 qw(keccak256_hex);

use Blockchain::Ethereum::ABI::Type;
use Blockchain::Ethereum::ABI::Type::Tuple;

sub new {
    my $class = shift;
    my $self  = {
        instances     => [],
        function_name => undef,
    };

    return bless $self, $class;
}

sub append {
    my ($self, %param) = @_;

    for my $type_signature (keys %param) {
        push(
            $self->{instances}->@*,
            Blockchain::Ethereum::ABI::Type->new(
                signature => $type_signature,
                data      => $param{$type_signature}));
    }

    return $self;
}

sub function {
    my ($self, $function_name) = @_;

    $self->{function_name} = $function_name;
    return $self;
}

sub generate_function_signature {
    my $self = shift;

    croak "Missing function name e.g. ->function('name')" unless $self->{function_name};

    my @instances = $self->{instances}->@*;

    my $signature = $self->{function_name} . '(';
    $signature .= sprintf("%s,", $_->{signature}) for @instances;
    chop $signature if scalar @instances;
    return $signature . ')';
}

sub encode_function_signature {
    my ($self, $signature) = @_;

    return sprintf("0x%.8s", keccak256_hex($signature // $self->generate_function_signature));
}

sub encode {
    my $self = shift;

    my $tuple = Blockchain::Ethereum::ABI::Type::Tuple->new;
    $tuple->{instances} = $self->{instances};

    my $encoded = $tuple->encode;
    my @data;
    push @data, $tuple->encode->@* if $encoded;
    unshift @data, $self->encode_function_signature if $self->{function_name};

    $self->_clean;

    return join('', @data);
}

sub _clean {
    my $self = shift;
    $self->{instances}     = [];
    $self->{function_name} = undef;
}

1;

__END__