File Coverage

blib/lib/Bio/GeneDesign/ReverseTranslate.pm

Criterion	Covered	Total	%
statement	58	61	95.0
branch	3	4	75.0
condition			n/a
subroutine	8	9	88.8
pod			n/a
total	69	74	93.2

=head1 NAME

Bio::GeneDesign::ReverseTranslate

=head1 VERSION

Version 5.56

=head1 DESCRIPTION

Reverse translate a sequence using rscu values to set replacement likelihood

=head1 AUTHOR

Sarah Richardson .

=cut

package Bio::GeneDesign::ReverseTranslate;
require Exporter;

use Bio::GeneDesign::Random qw(_random_index _weighted_rand);
use Carp;

use strict;
use warnings;

our $VERSION = 5.56;

use base qw(Exporter);
our @EXPORT_OK = qw(
  _list_algorithms
  _reversetranslate_balanced
  _reversetranslate_high
  _reversetranslate_random
);
our %EXPORT_TAGS =  (GD=> \@EXPORT_OK);

=head2 _list_algorithms

=cut

sub _list_algorithms
{
  my %hsh =
  (
    balanced => 'weighted averages',
    high     => 'uniformly most used',
    random   => 'random',
  );
  return \%hsh;
}

=head2 _reversetranslate_balanced

=cut

sub _reversetranslate_balanced
{
  my ($reverse_codon_table, $rscu_table, $pepseq) = @_;

  my %changehsh = ();
  foreach my $aa (keys %$reverse_codon_table)
  {
    $changehsh{$aa} = {};
    my @codons = @{$reverse_codon_table->{$aa}};
    my $count = scalar(@codons);
    my $checksum = 0;
    foreach my $coda (@codons)
    {
      my $likely = ($rscu_table->{$coda}) / $count;
      $changehsh{$aa}->{$coda} = $likely;
      $checksum += $likely;
    }
    if ($checksum == 0)
    {
      croak "This RSCU table has no positive values for $aa\n";
    }
  }

  my $newseq = q{};
  $newseq .= _weighted_rand($changehsh{$_}) foreach (split q{}, $pepseq);
  return $newseq;
}

=head2 _reversetranslate_high

=cut

sub _reversetranslate_high
{
  my ($reverse_codon_table, $rscu_table, $pepseq) = @_;
  my $aa_highs = {};
  foreach my $aa (keys %$reverse_codon_table)
  {
    my $myrscu = -1;
    foreach my $codon (@{$reverse_codon_table->{$aa}})
    {
      if ($rscu_table->{$codon} > $myrscu)
      {
        $aa_highs->{$aa} = $codon;
        $myrscu = $rscu_table->{$codon};
      }
    }
  }
  my $newseq = q{};
  $newseq .= $aa_highs->{$_} foreach (split q{}, $pepseq);
  return $newseq;
}

=head2 _reversetranslate_random

=cut

sub _reversetranslate_random
{
  my ($reverse_codon_table, $rscu_table, $pepseq) = @_;

  my $cod_highs = {};
  foreach my $aa (keys %{$reverse_codon_table})
  {
    $cod_highs->{$aa} = [];
    foreach my $codon (@{$reverse_codon_table->{$aa}})
    {
        push @{$cod_highs->{$aa}}, $codon;
    }
  }

  my $newseq = q{};
  foreach my $aa (split q{}, $pepseq)
  {
    my $index = _random_index(scalar(@{$cod_highs->{$aa}}));
    $newseq .= $cod_highs->{$aa}->[$index];
  }
  return $newseq;
}

1;

__END__