File Coverage

blib/lib/Benchmark/Report/GitHub.pm

Criterion	Covered	Total	%
statement	9	75	12.0
branch	0	10	0.0
condition	0	18	0.0
subroutine	3	7	42.8
pod	4	4	100.0
total	16	114	14.0

use 5.006;
use strict;
use warnings;

package Benchmark::Report::GitHub;

our $AUTHORITY = 'cpan:TOBYINK';
our $VERSION   = '0.001';

my @attributes = qw/ travis_repo_slug gh_name gh_email gh_token /;

sub new {
	my $class = shift;
	my $self  = bless +{ @_ }, $class;
	defined($self->{$_}) || die("missing required attribute: $_")
		for @attributes;
	return $self;
}

sub new_from_env {
	my $class = shift;

	my $missing = 0;
	for my $var (qw/ TRAVIS_REPO_SLUG GH_NAME GH_EMAIL GH_TOKEN /) {
		next if defined $ENV{$var};
		warn "missing: $var\n";
		$missing++;
	}
	die "correct environment variables are not set; bailing out"
		if $missing;

	$class->new(map +( $_ => $ENV{uc($_)} ), @attributes);
}

sub add_benchmark {
	my $self = shift;
	@_ == 3 or die("too many or too few arguments");
	push @{ $self->{benchmarks} ||= [] }, @_;
	return $self;
}

sub publish {
	my $self = shift;
	my %args = @_;

	my ($owner, $project) = split "/", $self->{travis_repo_slug};

	my @benchmarks = @{$self->{benchmarks}}
		or die "did you forget something?";

	system("rm -fr $project.wiki");
	system("git clone https://github.com/$owner/$project.wiki.git");

	my $perl = $args{perl_version} || $ENV{TRAVIS_PERL_VERSION} || $];
	my ($build_num, $build_id, $job_num, $job_id) = map {
		$args{$_} || $ENV{ "TRAVIS_" . uc($_) } || 'unknown'
	} qw( build_number build_id job_number job_id );

	my $page    = $args{page}       || "Benchmark_$job_id";
	my $title   = $args{page_title} || "Travis Job $job_num";
	my $idxpage = $args{index_page} || "Benchmarks";

	require Benchmark;
	require Cwd;
	require File::Path;

	RESULTS: {
		open my $fh, ">", "$project.wiki/$page.md";
		print $fh "# $title\n\n";
		print $fh "[Build log](https://travis-ci.org/$owner/$project/jobs/$job_id).\n\n";
		my $old = select($fh);
		while (@benchmarks) {
			my ($name, $times, $cases) = splice(@benchmarks, 0, 3);
			print "## $name\n\n";
			print "```\n";
			Benchmark::cmpthese($times, $cases);
			print "```\n\n";
		}
		select($old);
		close $fh;
	}

	INDEX: {
		open my $idx, ">>", "$project.wiki/$idxpage.md";
		print $idx "* [$title]($page)\n";
		close $idx;
	}

	UPLOAD: {
		my $orig = Cwd::cwd();
		chdir "$project.wiki";
		system("git config user.name '$ENV{GH_NAME}'");
		system("git config user.email '$ENV{GH_EMAIL}'");
		system("git config credential.helper 'store --file=.git/credentials'");
		open my $cred, '>', '.git/credentials';
		print $cred "https://$ENV{GH_TOKEN}:\@github.com\n";
		close $cred;
		system("git add .");
		system("git commit -a -m 'benchmarks for $job_num'");
		system("git push --all");
		system("rm '.git/credentials'");
		chdir($orig);
		File::Path::remove_tree("$project.wiki");
	}

	return "https://github.com/$owner/$project/wiki/$page";
}

1;

__END__