File Coverage

lib/Badger/Logic.pm

Criterion	Covered	Total	%
statement	88	93	94.6
branch	25	40	62.5
condition	15	30	50.0
subroutine	26	26	100.0
pod	9	10	90.0
total	163	199	81.9

#========================================================================
#
# Badger::Logic
#
# DESCRIPTION
#   Simple parser and evaluator for boolean logic expressions, e.g.
#   'purple or orange', 'animal and (eats_nuts or eats_berries)'
#
# AUTHOR
#   Andy Wardley
#
#========================================================================

package Badger::Logic;

use Badger::Class
    version   => 0.01,
    debug     => 0,
    base      => 'Badger::Base',
    as_text   => 'text',
    constants => 'HASH',
    constant  => {
        LOGIC => 'Badger::Logic',
    },
    exports   => {
        any   => 'LOGIC Logic',
    },
    messages  => {
        no_text   => 'No text expression specified.',
        no_rhs    => 'Missing expression following "%s"',
        bad_text  => 'Unexpected text in expression: %s',
        parse     => 'Could not parse logic expression: %s',
        no_rparen => 'Missing ")" at end of nested expression',
    };

our $NODE = {
    'item' => 'Badger::Logic::Item',
    'not'  => 'Badger::Logic::Not',
    'and'  => 'Badger::Logic::And',
    'or'   => 'Badger::Logic::Or',
};

*test = \&evaluate;


sub Logic {
    return @_
        ? LOGIC->new(@_)
        : LOGIC;
}

sub new {
    my $class = shift;
    my $text  = shift;
    return $class->error_msg('no_text')
        unless defined $text;
    bless {
        text => ref $text ? $text : \$text,
    }, $class;
}

sub evaluate {
    my $self = shift;
    my $args = @_ && ref $_[0] eq HASH ? shift : { @_ };
    $self->tree->evaluate($args);
}

sub tree {
    my $self = shift;
    return $self->{ tree }
       ||= $self->parse($self->{ text });
}

sub text {
    ${ shift->{ text } };
}

sub tree_text {
    shift->tree->text;
}

sub parse {
    my $self = shift;
    my $text = shift;
    my $tref = ref $text ? $text : \$text;
    $self->debug("parse($$tref)\n") if DEBUG;
    my $expr = $self->parse_expr($tref)
        || return $self->error_msg( parse => $$tref );
    $self->debug("expr: ", $expr->text) if DEBUG;
    if ($$tref =~ / \G \s* (.+) $/cigsx) {
        return $self->error_msg( bad_text => $1 );
    }
    return $expr;
}

sub parse_expr {
    my $self = shift;
    my $text = shift;
    my $left = $self->parse_unary($text) || return;

    $self->debug("got unary: ", $left->text) if DEBUG;

    if ($$text =~ / \G \s+ (and|or) \s+ /cigx) {
        my $op = $1;
        $self->debug("binary op: $op\n") if $DEBUG;
        my $right = $self->parse_expr($text)
            || return $self->error_msg( no_rhs => $op );
        return $NODE->{ lc $op }->new( $left, $right );
    }
    elsif ($$text =~ / \G \s* \( /cgx) {
        my $expr = $self->parse_expr($text)
            || return $self->error_msg( no_rhs => '(' );
        $$text =~ / \G \s* \) /cgx
            || return $self->error_msg('no_rparen');

        return $self->error_msg( bad_text => $1 );
    }

    return $left;
}

sub parse_unary {
    my $self = shift;
    my $text = shift;

    if ($$text =~ / \G \s* (not) \s+ /cigx) {
        my $op = $1;
        $self->debug("unary op: $op\n") if $DEBUG;
        my $right = $self->parse_term($text)
            || return $self->error_msg( no_rhs => $op );
        return $NODE->{ lc $op }->new($right);
    }
    return $self->parse_term($text)
        || $self->decline('Not a unary expression');
}

sub parse_term {
    my $self = shift;
    my $text = shift;

    if ($$text =~ / \G \s* (\w+) /cigx) {
        $self->debug("item: $1\n") if $DEBUG;
        return $NODE->{ item }->new($1);
    }
    elsif ($$text =~ / \G \s* (['"]) ((?:\\?.)*?) \1 /cigx) {
        $self->debug("string: $2\n") if $DEBUG;
        return $NODE->{ item }->new($2);
    }
    elsif ($$text =~ / \G \s* \( /cgx) {
        my $expr = $self->parse_expr($text)
            || return $self->error_msg( no_rhs => '(' );
        $$text =~ / \G \s* \) /cgx
            || return $self->error_msg('no_rparen');
        return $expr;
    }

    return $self->decline('Not a term');
}


#=======================================================================
# node types
#=======================================================================

package Badger::Logic::Expr;
use base 'Badger::Base';

sub new {
    my $class = shift;
    bless [ @_ ], $class;
}

package Badger::Logic::Item;
use base 'Badger::Logic::Expr';

sub evaluate {
    my $self = shift;
    my $args = @_ && ref $_[0] eq 'HASH' ? shift : { @_ };
    return $args->{ $self->[0] };
}

sub text {
    $_[0]->[0];
}

package Badger::Logic::Not;
use base 'Badger::Logic::Expr';

sub evaluate {
    my $self = shift;
    return $self->[0]->evaluate(@_) ? 0 : 1;
}

sub text {
    my $self = shift;
    '(not ' . $self->[0]->text . ')';
}

package Badger::Logic::And;
use base 'Badger::Logic::Expr';

sub evaluate {
    my $self = shift;
    return $self->[0]->evaluate(@_)
        && $self->[1]->evaluate(@_);
}

sub text {
    my $self = shift;
    '(' . $self->[0]->text . ' and ' . $self->[1]->text . ')';
}

package Badger::Logic::Or;
use base 'Badger::Logic::Expr';

use Badger::Debug ':all';
sub evaluate {
    my $self = shift;
    return $self->[0]->evaluate(@_)
        || $self->[1]->evaluate(@_);
}

sub text {
    my $self = shift;
    '(' . $self->[0]->text . ' or ' . $self->[1]->text . ')';
}

1;
__END__