File Coverage

inc/My/Module/Recommend.pm

Criterion	Covered	Total	%
statement	15	25	60.0
branch	0	6	0.0
condition			n/a
subroutine	5	7	71.4
pod	2	2	100.0
total	22	40	55.0

package My::Module::Recommend;

use strict;
use warnings;

use Carp;
use My::Module::Recommend::Any qw{ __any };
use My::Module::Recommend::None qw{ __none };

my @optionals = (
    __any( 'LWP::Protocol::https' => <<'EOD' ),
      This module is required if you want to use the https: URL scheme
      to access SIMBAD. If you intend to use only the default http:
      scheme this module is not needed.
EOD
    __any( 'SOAP::Lite'	=> <<'EOD' ),
      This module is required for the query() method. If you do not
      intend to use this method, SOAP::Lite is not needed.
EOD
    __any( 'XML::DoubleEncodedEntities' => <<'EOD' ),
      This module is not normally required. But at one point the SIMBAD
      service was double-encoding XML entities, and anything that has
      gone wrong once can go wrong again. If you find you need this
      module you cam install it and it will be used.
EOD
    __any( qw{ XML::Parser XML::Parser::Lite }	=> <<'EOD' ),
      One of these module is required to process the results of
      VO-format queries. If you do not intend to make VO-format queries,
      they are not needed.
EOD
    __any( 'Time::HiRes'	=> <<'EOD' ),
      This module can be used for more accurate control of query delay.
EOD
    __none( YAML	=> '' ),
);

my %core = map { $_ => 1 } qw{ Time::HiRes };

sub optionals {
    # As of Test::Builder 1.302190 (March 2 2022) Time::HiRes is needed
    # by Test::Builder, which is used by Test::More. It's a core module,
    # so it OUGHT to be available, though there are known downstream
    # packagers who strip core modules. Sigh. This is the reason I'm
    # stripping it here rather than removing it completely.
    return ( grep { ! $core{$_} } map { $_->modules() } @optionals );
}

sub recommend {
    my $need_some;
    foreach my $mod ( @optionals ) {
	defined( my $msg = $mod->recommend() )
	    or next;
	$need_some++
	    or warn <<'EOD';

The following optional modules were not available:
EOD
	warn "\n$msg";
    }
    $need_some
	and warn <<'EOD';

It is not necessary to install these now. If you decide to install them
later, this software will make use of them when it finds them.

EOD

    return;
}

1;

__END__