File Coverage

blib/lib/Astro/App/Satpass2/FormatTime/POSIX/Strftime.pm

Criterion	Covered	Total	%
statement	35	38	92.1
branch	8	12	66.6
condition	0	3	0.0
subroutine	10	10	100.0
pod	1	1	100.0
total	54	64	84.3

package Astro::App::Satpass2::FormatTime::POSIX::Strftime;

use 5.008;

use strict;
use warnings;

use parent qw{ Astro::App::Satpass2::FormatTime };

use Astro::Coord::ECI::Utils qw{ gm_strftime local_strftime };
use Astro::App::Satpass2::FormatTime::Strftime;
use Astro::App::Satpass2::Utils qw{ ARRAY_REF @CARP_NOT };
use POSIX ();

our $VERSION = '0.057';

sub format_datetime {
    my ( $self, $tplt, $time, $gmt ) = @_;
    $time = $self->__round_time_value( $time );
    defined $gmt or $gmt = $self->gmt();
    if ( ARRAY_REF eq ref $time ) {
	# NOTE that this is not documented, and is used only to
	# determine the maximum width generated by the given time
	# format, so I believe it can stand as-is. IF this is wrong AND
	# the strftime() behavior of Perl 5.39.8 and 5.39.9 makes it int
	# 5.40, I will need to set the zone to 'GMT' if $gmt is true.
	$gmt
	    and local $ENV{TZ} = 'GMT';
	return POSIX::strftime( $tplt, @{ $time } );
    } elsif ( $gmt ) {
	return gm_strftime( $tplt, $time );
    } else {
	my $tz = $self->tz();
	defined $tz
	    and $tz ne ''
	    and local $ENV{TZ} = $tz;
	return local_strftime( $tplt, $time );
    }
}

{
    my %adjuster = (
	year	=> sub { $_[0][5] = $_[1] - 1900; return },
	month	=> sub { $_[0][4] = $_[1] - 1; return },
	day	=> sub { $_[0][3] = $_[1]; return },
	hour	=> sub { $_[0][2] = $_[1]; return },
	minute	=> sub { $_[0][1] = $_[1]; return },
	second	=> sub { $_[0][0] = $_[1]; return },
    );

    sub __format_datetime_width_adjust_object {
	my ( undef, $obj, $name, $val ) = @_;	# Invocant unused
	$obj or $obj = [ 0, 0, 0, 1, 0, 200 ];
	$adjuster{$name}->( $obj, $val );
	return $obj;
    }

}

1;

__END__