File Coverage

blib/lib/ArrayDataRole/Source/LinesInDATA.pm

Criterion	Covered	Total	%
statement	46	53	86.7
branch	16	16	100.0
condition			n/a
subroutine	10	14	71.4
pod	3	10	30.0
total	75	93	80.6

package ArrayDataRole::Source::LinesInDATA;

use strict;
use Role::Tiny;
use Role::Tiny::With;
with 'ArrayDataRole::Spec::Basic';

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2024-05-06'; # DATE
our $DIST = 'ArrayDataRoles-Standard'; # DIST
our $VERSION = '0.010'; # VERSION

sub new {
    no strict 'refs'; ## no critic: TestingAndDebugging::RequireUseStrict

    my $class = shift;

    my $fh = \*{"$class\::DATA"};
    my $fhpos_data_begin;
    if (defined ${"$class\::_ArrayData_fhpos_data_begin_cache"}) {
        $fhpos_data_begin = ${"$class\::_ArrayData_fhpos_data_begin_cache"};
        seek $fh, $fhpos_data_begin, 0;
    } else {
        $fhpos_data_begin = ${"$class\::_ArrayData_fhpos_data_begin_cache"} = tell $fh;
    }

    bless {
        fh => $fh,
        fhpos_data_begin => $fhpos_data_begin,
        pos => 0, # iterator
    }, $class;
}

sub get_next_item {
    my $self = shift;
    die "StopIteration" if eof($self->{fh});
    chomp(my $elem = readline($self->{fh}));
    $self->{pos}++;
    $elem;
}

sub has_next_item {
    my $self = shift;
    !eof($self->{fh});
}

sub get_iterator_pos {
    my $self = shift;
    $self->{pos};
}

sub reset_iterator {
    my $self = shift;
    seek $self->{fh}, $self->{fhpos_data_begin}, 0;
    $self->{pos} = 0;
}

sub get_item_at_pos {
    my ($self, $pos) = @_;
    $self->reset_iterator if $self->{pos} > $pos;
    while (1) {
        die "Out of range" unless $self->has_next_item;
        my $item = $self->get_next_item;
        return $item if $self->{pos} > $pos;
    }
}

sub has_item_at_pos {
    my ($self, $pos) = @_;
    return 1 if $self->{pos} > $pos;
    while (1) {
        return 0 unless $self->has_next_item;
        $self->get_next_item;
        return 1 if $self->{pos} > $pos;
    }
}

sub fh {
    my $self = shift;
    $self->{fh};
}

sub fh_min_offset {
    my $self = shift;
    $self->{fhpos_data_begin};
}

sub fh_max_offset { undef }

1;
# ABSTRACT: Role to access array data from DATA section, one line per element

__END__