File Coverage

blib/lib/Array/Util/MultiTarget.pm

Criterion	Covered	Total	%
statement	75	75	100.0
branch	20	20	100.0
condition			n/a
subroutine	10	10	100.0
pod	7	7	100.0
total	112	112	100.0

## no critic: Subroutines::ProhibitSubroutinePrototypes
package Array::Util::MultiTarget;

use strict;
use warnings;

use Exporter qw(import);

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2023-12-03'; # DATE
our $DIST = 'Array-Util-MultiTarget'; # DIST
our $VERSION = '0.001'; # VERSION

our @EXPORT_OK = qw(
                       mtpop
                       mtpush
                       mtsplice
                       mtremovestr
                       mtremoveallstr
                       mtremovenum
                       mtremoveallnum
               );

sub mtpop($) {
    my $arys = shift;

    my @res;
    for my $ary (@$arys) { push @res, pop @$ary }
    @res;
}

sub mtpush($@) {
    my $arys = shift;

    for my $ary (@$arys) { push @$ary, @_ }
}

sub mtsplice($$;$@) {
    my $arys = shift;
    my $offset = shift;
    my $len; $len = shift if @_;

    my @res;
    for my $ary (@$arys) {
        if (defined $len) {
            push @res, [splice @$ary, $offset, $len, @_];
        } else {
            push @res, [splice @$ary, $offset];
        }
    }
    @res;
}

sub mtremovestr {
    my $arys = shift;
    my $wanted = shift;

    my $pos;
    for my $i (0 .. $#{ $arys->[0] }) {
        if ($arys->[0][$i] eq $wanted) {
            $pos = $i; last;
        }
    }
    return unless defined $pos;

    for my $ary (@$arys) {
        splice @$ary, $pos, 1;
    }

    $pos;
}

sub mtremoveallstr {
    my $arys = shift;
    my $wanted = shift;

    my @pos;
    for my $i (0 .. $#{ $arys->[0] }) {
        if ($arys->[0][$i] eq $wanted) {
            unshift @pos, $i;
        }
    }
    return unless @pos;

    for my $ary (@$arys) {
        for (@pos) {
            splice @$ary, $_, 1;
        }
    }

    reverse @pos;
}

sub mtremovenum {
    my $arys = shift;
    my $wanted = shift;

    my $pos;
    for my $i (0 .. $#{ $arys->[0] }) {
        if ($arys->[0][$i] == $wanted) {
            $pos = $i; last;
        }
    }
    return unless defined $pos;

    for my $ary (@$arys) {
        splice @$ary, $pos, 1;
    }

    $pos;
}

sub mtremoveallnum {
    my $arys = shift;
    my $wanted = shift;

    my @pos;
    for my $i (0 .. $#{ $arys->[0] }) {
        if ($arys->[0][$i] == $wanted) {
            unshift @pos, $i;
        }
    }
    return unless @pos;

    for my $ary (@$arys) {
        for (@pos) {
            splice @$ary, $_, 1;
        }
    }

    reverse @pos;
}

1;
# ABSTRACT: Apply an operation to multiple arrays

__END__