File Coverage

blib/lib/Array/Set/Naive.pm

Criterion	Covered	Total	%
statement	54	54	100.0
branch	17	24	70.8
condition			n/a
subroutine	13	13	100.0
pod	4	4	100.0
total	88	95	92.6

package Array::Set::Naive;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2021-05-15'; # DATE
our $DIST = 'Array-Set-Naive'; # DIST
our $VERSION = '0.001'; # VERSION

use strict;
use warnings;

# not yet used, problem with hang during build
#use List::Keywords qw(any);
use List::Util qw(any);

use Exporter qw(import);
our @EXPORT_OK = qw(set_diff set_symdiff set_union set_intersect);

sub set_diff {
    my $opts = ref($_[0]) eq 'HASH' ? shift : {};

    my $set1 = @_ ? shift : [];
    my $res = $set1;
    while (@_) {
        my $set2 = shift;
        $res = [];
        for my $el (@$set1) {
            push @$res, $el unless any { $_ eq $el } @$set2;
            $set1 = $res;
        }
    }
    $res;
}

sub set_symdiff {
    my $opts = ref($_[0]) eq 'HASH' ? shift : {};

    my $res = [];
    for my $i (0..$#_) {
        my $set1 = $_[$i];
      ELEM:
        for my $el1 (@$set1) {
            next ELEM if any { $_ eq $el1 } @$res;
            for my $j (0..$#_) {
                next if $i == $j;
                my $set2 = $_[$j];
                next ELEM if any { $_ eq $el1 } @$set2;
            }
            push @$res, $el1;
        }
    }
    $res;
}

sub set_union {
    my $opts = ref($_[0]) eq 'HASH' ? shift : {};

    my $res = [];
    for my $set (@_) {
        for my $el (@$set) {
            push @$res, $el unless any { $_ eq $el } @$res;
        }
    }
    $res;
}

sub set_intersect {
    my $opts = ref($_[0]) eq 'HASH' ? shift : {};

    return [] unless @_;
    my $set1 = shift @_;
    my $res = [];
  EL:
    for my $el (@$set1) {
        for my $set (@_) {
            next EL unless any { $_ eq $el } @$set;
        }
        push @$res, $el;
    }
    $res;
}

1;
# ABSTRACT: Like Array::Set, but uses naive algorithms

__END__