File Coverage

blib/lib/Array/Pick/Scan.pm

Criterion	Covered	Total	%
statement	28	35	80.0
branch	8	14	57.1
condition	1	2	50.0
subroutine	5	5	100.0
pod	1	1	100.0
total	43	57	75.4

package Array::Pick::Scan;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2020-05-18'; # DATE
our $DIST = 'Array-Pick-Scan'; # DIST
our $VERSION = '0.002'; # VERSION

use 5.010001;
use strict;
use warnings;

use Exporter qw(import);
our @EXPORT_OK = qw(random_item);

sub random_item {
    my ($src, $num_items) = @_;
    my $ref = ref $src;

    $num_items //= 1;

    if ($ref eq 'ARRAY') {
        my $ary = $src;
        my $ary_size = @$ary;

        if ($num_items == 1) {
            return $ary->[rand() * $ary_size];
        } else {
            my @items;
            for my $i (0..$ary_size-1) {
                if (@items < $num_items) {
                    # we haven't reached $num_items, insert item to array in a
                    # random position
                    splice @items, rand(@items+1), 0, $ary->[$i];
                } else {
                    # we have reached $num_items, just replace an item randomly,
                    # using algorithm from Learning Perl, slightly modified
                    rand($i+1) < @items and
                        splice @items, rand(@items), 1, $ary->[$i];
                }
            }
            return @items;
        }
    } elsif ($ref eq 'CODE') {
        my $iter = $src;
        my @items;
        my $i = -1;
        while (defined(my $item = $iter->())) {
            $i++;
            if (@items < $num_items) {
                # we haven't reached $num_items, insert item to array in a
                # random position
                splice @items, rand(@items+1), 0, $item;
            } else {
                # we have reached $num_items, just replace an item randomly,
                # using algorithm from Learning Perl, slightly modified
                rand($i+1) < @items and splice @items, rand(@items), 1, $item;
            }
        }
        return @items;
    } else {
        die "Please specify arrayref or coderef iterator as source of items";
    }
}

1;
# ABSTRACT: Pick random items from an array (or iterator), without duplicates

__END__