File Coverage

lib/Archive/Lha/Header/Level1.pm

Criterion	Covered	Total	%
statement	57	64	89.0
branch	6	12	50.0
condition			n/a
subroutine	7	7	100.0
pod	1	1	100.0
total	71	84	84.5

package Archive::Lha::Header::Level1;

use strict;
use warnings;
use Carp;
use Archive::Lha::Constants;
use Archive::Lha::Header::Base;
use Archive::Lha::Header::Utils;

sub new {
  my ($class, $stream) = @_;

  my $start = $stream->tell;
  my $size  = ord($stream->read(1)) + 2;

  croak "Header is broken: size is too small: $size" if $size < 27;

  $stream->seek($start);
  my $buf = $stream->read($size);

  my $checksum  = ord(substr($buf, 1, 1));
  my $checksum1 = defined &Archive::Lha::Header::Utils::checksum
    ? Archive::Lha::Header::Utils::checksum($buf, 2)
    : do { my $s = 0; $s += $_ for unpack 'C*', substr($buf, 2); $s & CHAR_MAX };
  croak "Header is broken: checksum $checksum/$checksum1"
    unless $checksum == $checksum1;

  my %header;
  $header{header_top}      = $start;
  $header{header_size}     = $size;
  $header{header_checksum} = $checksum;
  $header{method}          = substr($buf, 3, 3);
  $header{skip_size}       = unpack 'V', substr($buf,  7, 4);
  $header{original_size}   = unpack 'V', substr($buf, 11, 4);
  $header{timestamp}       = unpack 'V', substr($buf, 15, 4);

  my $filename_length = ord(substr($buf, 21, 1));
  $header{filename}   = substr($buf, 22, $filename_length);
  $header{filename}   =~ s/\0.*//s;
  $header{crc16}      = unpack 'v', substr($buf, 22 + $filename_length, 2);
  $header{os}         = _os_id( substr($buf, 24 + $filename_length, 1) );

  my $ext_from = 25 + $filename_length;
  my $ext_to   = $size - 3;
  if ($ext_from < $ext_to) {
    my (undef, $ext) = _extended_header_buf($buf, $ext_from, $ext_to - $ext_from + 2);
    %header = (%header, %{ $ext }) if %{ $ext };
  }

  my $extended_size_total = 0;
  my $extended_size = unpack 'v', substr($buf, -2, 2);
  while ($extended_size) {
    my $chunk = $stream->read($extended_size);
    $extended_size_total += $extended_size;
    my ($next, $hash) = _extended_header_buf($chunk, 0, $extended_size);
    %header = (%header, %{ $hash }) if %{ $hash };
    $extended_size = $next;
  }
  $header{encoded_size} = $header{skip_size} - $extended_size_total;

  $header{data_top}    = $start + $size + $extended_size_total;
  $header{next_header} = $header{data_top} + $header{encoded_size};

  bless \%header, $class;
}

1;

__END__