File Coverage

blib/lib/Archive/Har/Creator.pm

Criterion	Covered	Total	%
statement	9	73	12.3
branch	0	34	0.0
condition	0	6	0.0
subroutine	3	9	33.3
pod	4	5	80.0
total	16	127	12.6

package Archive::Har::Creator;

use warnings;
use strict;
use Carp();

our $VERSION = 0.19;

sub new {
    my ( $class, $params ) = @_;
    my $self = {};
    bless $self, $class;
    if ( defined $params ) {
        $self->name( $params->{name} );
        $self->version( $params->{version} );
        if ( defined $params->{comment} ) {
            $self->comment( $params->{comment} );
        }
        foreach my $key ( sort { $a cmp $b } keys %{$params} ) {
            if ( $key =~ /^_[[:alnum:]]+$/smx ) {    # private fields
                $self->$key( $params->{$key} );
            }
        }
    }
    return $self;
}

sub name {
    my ( $self, $new ) = @_;
    my $old = $self->{name};
    if ( @_ > 1 ) {
        if ( defined $new ) {
            $self->{name} = $new;
        }
        else {
            $self->{name} = 'Unknown';
        }
    }
    if ( ( defined $old ) && ( $old eq 'Unknown' ) ) {
        return;
    }
    else {
        return $old;
    }
}

sub version {
    my ( $self, $new ) = @_;
    my $old = $self->{version};
    if ( @_ > 1 ) {
        if ( defined $new ) {
            $self->{version} = $new;
        }
        else {
            $self->{version} = 'Unknown';
        }
    }
    if ( ( defined $old ) && ( $old eq 'Unknown' ) ) {
        return;
    }
    else {
        return $old;
    }
}

sub comment {
    my ( $self, $new ) = @_;
    my $old = $self->{comment};
    if ( @_ > 1 ) {
        $self->{comment} = $new;
    }
    return $old;
}

sub AUTOLOAD {
    my ( $self, $new ) = @_;

    my $name = $Archive::Har::Creator::AUTOLOAD;
    $name =~ s/.*://smx;    # strip fully-qualified portion

    my $old;
    if ( $name =~ /^_[[:alnum:]]+$/smx ) {    # private fields
        $old = $self->{$name};
        if ( @_ > 1 ) {
            $self->{$name} = $new;
        }
    }
    else {
        Carp::croak(
"$name is not specified in the HAR 1.2 spec and does not start with an underscore"
        );
    }
    return $old;
}

sub TO_JSON {
    my ($self) = @_;
    my $json = {};
    if ( defined $self->name() ) {
        $json->{name} = $self->name();
    }
    else {
        $json->{name} = 'Unknown';
    }
    if ( defined $self->version() ) {
        $json->{version} = $self->version();
    }
    else {
        $json->{version} = 'Unknown';
    }
    if ( defined $self->comment() ) {
        $json->{comment} = $self->comment();
    }
    foreach my $key ( sort { $a cmp $b } keys %{$self} ) {
        next if ( !defined $self->{$key} );
        if ( $key =~ /^_[[:alnum:]]+$/smx ) {    # private fields
            $json->{$key} = $self->{$key};
        }
    }
    return $json;
}

1;
__END__