File Coverage

blib/lib/Arango/Tango.pm

Criterion	Covered	Total	%
statement	28	52	53.8
branch	0	4	0.0
condition	0	25	0.0
subroutine	10	15	66.6
pod	4	4	100.0
total	42	100	42.0

# ABSTRACT: A simple interface to ArangoDB REST API
package Arango::Tango;
$Arango::Tango::VERSION = '0.019';
use base 'Arango::Tango::API';
use Arango::Tango::Database;
use Arango::Tango::Collection;

use strict;
use warnings;
use HTTP::Tiny;
use JSON;
use MIME::Base64 3.11 'encode_base64url';
use URI::Encode qw(uri_encode);


BEGIN {
Arango::Tango::API::_install_methods "Arango::Tango" => {
    engine                  => { rest => [ get => '_api/engine' ] },
    cluster_endpoints       => { rest => [ get => '_api/cluster/endpoints' ] },
    server_id               => { rest => [ get => '_admin/server/id' ] },
    status                  => { rest => [ get => '_admin/status' ] },
    time                    => { rest => [ get => '_admin/time' ] },
    statistics              => { rest => [ get => '_admin/statistics' ] },
    statistics_description  => { rest => [ get => '_admin/statistics-description' ] },
    target_version          => { rest => [ get => '_admin/database/target-version' ] },
    log_level               => { rest => [ get => '_admin/log/level' ] },
    server_role             => { rest => [ get => '_admin/server/role' ] },
    server_mode             => { rest => [ get => '_admin/server/mode' ] },
    server_availability     => { rest => [ get => '_admin/server/availability' ] },
    list_users              => { rest => [ get => '_api/user' ] },
    current_database        => { rest => [ get => '_api/database/current' ] },

    version                 => { rest => [ get => '_api/version' ], schema => {  details => { type => 'boolean' } }},

    delete_database         => {
        signature => [ 'name' ],
        rest => [ delete => '_api/database/{name}' ]
    },

    delete_user             => {
        signature => [ 'username' ],
        rest => [ delete => '_api/user/{username}' ]
    },

    replace_user            => {
        signature => [ 'username' ],
        rest => [ put => '_api/user/{username}' ],
        schema => { password => { type => 'string'  },
                    active   => { type => 'boolean' },
                    extra    => { type => 'object', additionalProperties => 1 }}},

    user                    => {
        signature => [ 'username' ],
        rest => [ get => '_api/user/{username}' ] },

    update_user             => {
        signature => [ 'user' ],
        rest => [ patch => '_api/user/{user}' ],
        schema => { password => { type => 'string'  },
                    active   => { type => 'boolean' },
                    extra    => { type => 'object', additionalProperties => 1 }}},

    user_databases  => {
        signature => [ 'username' ],
        rest      => [ get => '_api/user/{username}/database' ],
        schema    => { full => {type => 'boolean' }}},

    get_access_level => {
        signature => ['username','database','?collection'],
        rest      => [ get => '_api/user/{username}/database/{database}/{collection}' ],
       },

    clear_access_level => {
        signature => ['username','database','?collection'],
        rest      => [ delete => '_api/user/{username}/database/{database}/{collection}' ],
       },

    set_access_level => {
        signature => ['username', 'grant', 'database', '?collection'],
        rest      => [ put => '_api/user/{username}/database/{database}/{collection}' ],
        schema    => { grant => { type => 'string', enum => [qw'rw ro none'], default => 'none' }},
    },

    create_database => {
        signature => [ 'name' ],
        rest => [ post => '_api/database' ],
        schema  => { name  => { type => 'string' },
                     users => {
                         type => 'array',
                         items => {
                             type => 'object',
                             additionalProperties => 0,
                             properties => {
                                 username => { type => 'string' },
                                 passwd   => { type => 'string'},
                                 active   => { type => 'boolean' },
                                 extra    => { type => 'object', additionalProperties => 1 }
                             }}}},
        builder => sub {
            my ($self, %params) = @_;
            return Arango::Tango::Database->_new(arango => $self, 'name' => $params{name});
        },
    },

    create_user => {
        signature => [ 'user' ],
        rest => [ post => '_api/user'],
        schema => {
            password => { type => 'string'  },
            active   => { type => 'boolean' },
            user     => { type => 'string'  },
            extra    => { type => 'object', additionalProperties => 1 },
        }
    },

    log => {
        rest => [ get => '_admin/log' ],
        schema => {
            upto   => { type => 'string', default => 'info', enum => [qw'fatal error warning info debug 0 1 2 3 4'] },
            level  => { type => 'string', default => 'info', enum => [qw'fatal error warning info debug'] },
            size   => { type => 'integer', minimum => 0 },
            offset => { type => 'integer', minimum => 0 },
            search => { type => 'string' },
            sort   => { type => 'string', default => 'asc', enum => [qw'asc desc'] }, # asc, desc
        }
    }
};

}



sub new {
    my ($package, %opts) = @_;
    my $self = bless { %opts } => $package;

    $self->{host} ||= $ENV{ARANGO_DB_HOST} || "localhost";
    $self->{port} ||= $ENV{ARANGO_DB_PORT} || 8529;

    $self->{scheme} ||= $ENV{ARANGO_DB_SCHEME} || 'http';

    $self->{username} ||= $ENV{ARANGO_DB_USERNAME} || "root";
    $self->{password} ||= $ENV{ARANGO_DB_PASSWORD} || "";

    $self->{headers} = {
        Authorization => $self->_auth,
        Accept => 'application/json',
    };
    $self->{http} = HTTP::Tiny->new(default_headers => $self->{headers});

    return $self;
}

sub _auth {
    my $self = shift;
    return "Basic " . encode_base64url( $self->{username} . ":" . $self->{password} );
}

sub database {
    my ($self, $name) = @_;
    my $databases = $self->list_databases;
    if (grep {$name eq $_} @$databases) {
        return Arango::Tango::Database->_new( arango => $self, name => $name);
    } else {
        die "Arango::Tango | Database not found."
    }
}

sub list_databases {
    my $self = shift;
    return  $self->_api('accessible_databases')->{result};
}


sub http_status {
    my $self = shift;
    return exists($self->{last_error}) ? $self->{last_error} : 0;
}

1;

__END__