File Coverage

blib/lib/Arango/DB.pm

Criterion	Covered	Total	%
statement	39	72	54.1
branch	0	6	0.0
condition	0	26	0.0
subroutine	13	27	48.1
pod	8	8	100.0
total	60	139	43.1

# ABSTRACT: A simple interface to ArangoDB REST API
package Arango::DB;
$Arango::DB::VERSION = '0.006';
use base 'Arango::DB::API';
use Arango::DB::Database;
use Arango::DB::Collection;

use strict;
use warnings;
use HTTP::Tiny;
use JSON;
use MIME::Base64 3.11 'encode_base64url';
use URI::Encode qw(uri_encode);
use JSON::Schema::Fit 0.04;

sub new {
    my ($package, %opts) = @_;
    my $self = bless { %opts } => $package;

    $self->{host} ||= $ENV{ARANGO_DB_HOST} || "localhost";
    $self->{port} ||= $ENV{ARANGO_DB_PORT} || 8529;

    $self->{username} ||= $ENV{ARANGO_DB_USERNAME} || "root";
    $self->{password} ||= $ENV{ARANGO_DB_PASSWORD} || "";

    $self->{headers} = {
        Authorization => $self->_auth
    };
    $self->{http} = HTTP::Tiny->new(default_headers => $self->{headers});

    return $self;
}


use Sub::Install qw(install_sub);
use Sub::Name qw(subname);
BEGIN {
    my $package = __PACKAGE__;
    for my $m (qw'version status time statistics statistics_description') {
        install_sub {
            code => subname(
                "${package}::$m",
                sub { my ($self, %opts) = @_; return $self->_api($m, \%opts) }
               ),
                 into => $package,
                 as => $m
             };
    }
}

sub _auth {
    my $self = shift;
    return "Basic " . encode_base64url( $self->{username} . ":" . $self->{password} );
}

sub list_collections {
    my ($self, $name) = @_;
    return $self->_api('list_collections', { database => $name })->{result};
}

sub database {
    my ($self, $name) = @_;
    my $databases = $self->list_databases;
    if (grep {$name eq $_} @$databases) {
        return Arango::DB::Database->_new( arango => $self, name => $name);
    } else {
        die "Arango::DB | Database not found."
    }
}

sub list_databases {
    my $self = shift;
    return  $self->_api('list_databases')->{result};
}

sub create_database {
    my ($self, $name) = @_;
    return $self->_api('create_database', { name => $name });
}

sub delete_database {
    my ($self, $name) = @_;
    return $self->_api('delete_database', { name => $name });
}

sub create_user {
    my ($self, $username, %opts) = @_;
    die "Arango::DB | No username suplied" unless defined $username and length $username;
    return $self->_api('create_user', { %opts, user => $username });
}

sub delete_user {
    my ($self, $username) = @_;
    die "Arango::DB | No username suplied" unless defined $username and length $username;
    return $self->_api('delete_user', { username => $username });
}

1;

__END__