File Coverage

blib/lib/App/sdview/Output/Terminal.pm

Criterion	Covered	Total	%
statement	26	42	61.9
branch	0	4	0.0
condition	0	3	0.0
subroutine	9	12	75.0
pod	0	3	0.0
total	35	64	54.6

#  You may distribute under the terms of either the GNU General Public License
#  or the Artistic License (the same terms as Perl itself)
#
#  (C) Paul Evans, 2021-2024 -- [e-mail]

use v5.26;
use warnings;
use utf8;

use Object::Pad 0.807;

package App::sdview::Output::Terminal 0.20;
class App::sdview::Output::Terminal :strict(params);

inherit App::sdview::Output::Formatted;

use constant format => "terminal";

use Scalar::Util qw( blessed );
use String::Tagged::Terminal 0.08; # for OSC 8 hyperlink support
use Term::Size;

=head1 NAME

C - generate terminal formatted output from L

=head1 SYNOPSIS

   $ sdview README.pod -o terminal

(though this is likely the default output mode)

=head1 DESCRIPTION

This output module generates formatted output with embedded terminal control
codes, allowing colours and formatting information to be displayed on a
terminal.

By default, if the process standard output stream appears to be a TTY device,
the output is piped via F to act as a simple iteractive pager.

=cut

=head1 OPTIONS

=over 4

=item -O nopager

Disables use of F as an output pager, causing output to be printed to
the terminal directly.

=item -O width=NN

Overrides the detected width of the terminal.

=back

=cut

field $pager :param = !!1;

# TODO: Is this the neatest way to do this?
ADJUST :params ( :$nopager = undef ) {
   $pager = !!0 if $nopager;
}

field $width :param :reader = scalar Term::Size::chars;

method setup_output ()
{
   if( $pager and -T STDOUT ) {
      open my $outh, "|-", "less", "-R";
      $outh->binmode( ":encoding(UTF-8)" );
      select $outh;
   }
   else {
      STDOUT->binmode( ":encoding(UTF-8)" );
   }
}

method say ( @s )
{
   say map {
      blessed $_ ? String::Tagged::Terminal->new_from_formatting($_)->build_terminal : "$_"
   } @s;
}

=head1 AUTHOR

Paul Evans

=cut

0x55AA;