File Coverage

blib/lib/App/pwhich.pm

Criterion	Covered	Total	%
statement	27	34	79.4
branch	8	16	50.0
condition	0	2	0.0
subroutine	6	8	75.0
pod	0	1	0.0
total	41	61	67.2

package App::pwhich;

use strict;
use warnings;
use 5.008001;
use File::Which qw( which );
use Getopt::Std qw( getopts );

# ABSTRACT: Perl-only `which`
our $VERSION = '1.15'; # VERSION

sub main
{
  local @ARGV = @_;

  my %opts;
  getopts('avs', \%opts) || return _usage();

  return _version() if $opts{v};

  return _usage() unless @ARGV;

  foreach my $file (@ARGV)
  {
    my @result = $opts{a}
    ? which($file)
    : scalar which($file);

    # We might end up with @result = (undef) -> 1 elem
    @result = () unless defined $result[0];
    unless($opts{s})
    {
      print "$_\n" for grep { defined } @result;
    }

    unless (@result)
    {
      print STDERR "$0: no $file in PATH\n" unless $opts{s};
      return 1;
    }
  }

  return 0;
}

sub _version
{
  my $my_version = $App::pwhich::VERSION || 'dev';
  print <<"END_TEXT";
This is pwhich running File::Which version $File::Which::VERSION
                       App::pwhich version $my_version

Copyright 2002 Per Einar Ellefsen

Some parts Copyright 2009 Adam Kennedy

Other parts Copyright 2015 Graham Ollis

This program is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.
END_TEXT
  2;
}

sub _usage
{
  print <<"END_TEXT";
Usage: $0 [-a] [-s] [-v] programname [programname ...]
      -a        Print all matches in PATH, not just the first.
      -v        Prints version and exits
      -s        Silent mode

END_TEXT
  1;
}

1;

__END__