File Coverage

script/proxyforurl

Criterion	Covered	Total	%
statement	12	17	70.5
branch			n/a
condition			n/a
subroutine	4	5	80.0
pod			n/a
total	16	22	72.7

#!/usr/bin/env perl
use Mojolicious::Lite -signatures;

use Mojo::Util  qw(network_contains);
use NetAddr::IP ();
use Socket      qw(AF_INET AF_INET6 inet_ntop getaddrinfo unpack_sockaddr_in unpack_sockaddr_in6);

get
  '/' => {layout => 'pac'},
  'index';

get '/pac', [format => [qw(js)]], => 'pac';

post '/v1/gethostbyname' => sub ($c) {
  return $c->render(text => 'Host missing.', status => 400) unless my $host = $c->param('host');
  return $c->render(text => "Invalid host: $host", status => 400) unless $host =~ /[A-Za-z:\.]/;

  $c->res->headers->cache_control('max-age=600');
  return $c->render_later->host_to_ip_p($host)->then(sub ($addr) {
    return $c->render(text => "No IP found for $host", status => 400) unless $addr;
    return $c->render(text => $addr);
  })->catch(
    sub ($err, @) {
      return $c->render(text => exception_to_text($err), status => 500);
    }
  );
};

post '/v1/is-in-net' => sub ($c) {
  my ($ip, $net, $mask) = map { $c->param($_) } qw(ip net mask);
  return $c->render(text => 'IP or Net is missing.', status => 400)
    unless 2 == grep { $_ && $_ =~ /[:\.]/ } $ip, $net;
  return $c->render(text => 'Mask is invalid or missing.', status => 400)
    unless $mask and $mask =~ /^\d{1,3}$/;

  $c->res->headers->cache_control('max-age=600');
  return $c->render_later->host_to_ip_p($ip)->then(sub ($resolved) {
    $c->render(text => $resolved && network_contains("$net/$mask", $resolved) ? 1 : 0);
  })->catch(
    sub ($err, @) {
      $c->render(text => exception_to_text($err), status => 500);
    }
  );
};

get '/v1/template' => {template => 'template'};

helper host_to_ip_p => sub ($c, $host) {
  return Mojo::IOLoop->subprocess->run_p(sub (@) {
    local $SIG{ALRM} = sub { die 'Timeout!' };
    alarm 2;
    my ($err, @info) = getaddrinfo $host;
    return undef if $err;

    @info = grep { $_->{family} & (AF_INET6 | AF_INET) } @info;
    for my $item (@info) {
      $item->{pri} = $item->{family} == AF_INET6 ? 0 : 1;
      @$item{qw(port ip)}
        = $item->{family} == AF_INET6
        ? unpack_sockaddr_in6($item->{addr})
        : unpack_sockaddr_in($item->{addr});
      $item->{ip} = inet_ntop @$item{qw(family ip)};
    }

    # IPv4 before IPv6
    @info = sort { $b->{pri} <=> $a->{pri} } @info;

    return @info && $info[0]{ip} || undef;
  })->catch(
    sub ($err, @) {
      return $err =~ m!Timeout! ? undef : Mojo::Promise->reject($err);
    }
  );
};

if (my $env_base = $ENV{PROXYFORURL_X_REQUEST_BASE}) {
  $env_base = '' unless $env_base =~ m!^http!;
  hook before_dispatch => sub ($c) {
    return unless my $base = $env_base || $c->req->headers->header('X-Request-Base');
    $c->req->url->base(Mojo::URL->new($base));
  };
}

app->renderer->paths([$ENV{PROXYFORURL_TEMPLATES} || 'templates']);
app->static->paths([$ENV{PROXYFORURL_PUBLIC}      || 'public']);
app->config(brand_name => $ENV{PROXYFORURL_BRAND_NAME} || 'ProxyForURL');
app->config(brand_url  => $ENV{PROXYFORURL_BRAND_URL}  || '/');
app->start;

sub exception_to_text ($err) {
  $err =~ s!\sat\s\S+.*?line.*!!s;
  return $err;
}

__DATA__