File Coverage

blib/lib/App/plackbench/Stats.pm

Criterion	Covered	Total	%
statement	68	68	100.0
branch	16	16	100.0
condition	2	2	100.0
subroutine	18	18	100.0
pod	11	12	91.6
total	115	116	99.1

package App::plackbench::Stats;
$App::plackbench::Stats::VERSION = '0.7';
use strict;
use warnings;
use autodie;
use v5.10;

use List::Util qw( sum reduce );

sub new {
    my $class = shift;
    my @self = sort { $a <=> $b } @_;
    return bless \@self, $class;
}

sub insert {
    my $self = shift;
    my $n = shift;

    push @{$self}, $n;
    return $self->count();
}

sub finalize {
    my $self = shift;

    @{$self} = sort { $a <=> $b } @{$self};
    return $self;
}

sub count {
    my $self = shift;
    return scalar @{$self};
}

sub mean {
    my $self = shift;

    return unless $self->count();
    return $self->elapsed() / $self->count();
}

sub median {
    my $self = shift;

    return unless $self->count();

    if ($self->count() % 2 == 1) {
        return $self->[$self->count() / 2];
    }

    my $index_a = ($self->count() / 2) + 0.5;
    my $index_b = ($self->count() / 2) - 0.5;
    my $a = $self->[$index_a];
    my $b = $self->[$index_b];
    return ($a + $b) / 2;
}

sub min {
    my $self = shift;

    return unless $self->count();
    return $self->[0];
}

sub max {
    my $self = shift;
    return unless $self->count();
    return $self->[-1];
}

sub standard_deviation {
    my $self = shift;

    return 0 unless $self->count();
    my $mean = $self->mean();

    my $differences_sum = reduce {
        $a + ( ( $b - $mean )**2 );
    }
    0, @{$self};

    my $sd = sqrt( $differences_sum / $self->count() );
    return $sd;
}

sub percentile {
    my $self = shift;
    my $percentile = shift;

    my $n = int(( $percentile / 100 ) * $self->count() + 0.5) - 1;
    $n = 0 if $n < 0;
    return $self->[$n];
}

sub elapsed {
    my $self = shift;

    return sum(@$self) || 0;
}

sub rate {
    my $self = shift;

    return 0 unless $self->elapsed();
    return $self->count() / $self->elapsed();
}

1;

__END__