File Coverage

blib/lib/App/highlight.pm

Criterion	Covered	Total	%
statement	65	73	89.0
branch	25	28	89.2
condition	15	21	71.4
subroutine	9	9	100.0
pod	3	3	100.0
total	117	134	87.3

use strict;
use warnings;

package App::highlight;
{
  $App::highlight::VERSION = '0.14';
}
use base 'App::Cmd::Simple';

use Try::Tiny;
use Module::Load qw(load);
use Getopt::Long::Descriptive;

my $COLOR_SUPPORT = 1;
my @COLORS;

my %COLOR_MODULES = (
    'Term::ANSIColor' => [ 'color', 'colored' ],
);

# windows support
if ($^O eq 'MSWin32') {
    $COLOR_MODULES{'Win32::Console::ANSI'} = [];
}

try {
    for my $module (sort keys %COLOR_MODULES) {
        load($module, @{ $COLOR_MODULES{$module} });
    }

    @COLORS = map { [ color("bold $_"), color('reset') ] } (
        qw(red green yellow blue magenta cyan)
    );
}
catch {
    $COLOR_SUPPORT = 0;
};

my @NOCOLORS = (
    [ '<<', '>>' ],
    [ '[[', ']]' ],
    [ '((', '))' ],
    [ '{{', '}}' ],
    [ '**', '**' ],
    [ '__', '__' ],
);

sub opt_spec {
    return (
        [
            one_of => [
                [ 'color|c'    => "use terminal color for highlighting (default)" ],
                [ 'no-color|C' => "don't use terminal color"                      ],
            ],
        ],
        [
            one_of => [
                [ 'escape|e'            => "auto-escape input (default)"          ],
                [ 'no-escape|regex|n|r' => "don't auto-escape input (regex mode)" ],
            ]
        ],
        [ 'ignore-case|i'     => "ignore case for matches"              ],
        [ 'full-line|l'       => "highlight the whole matched line"     ],
        [ 'one-color|o'       => "use only one color for all matches"   ],
        [ 'show-bad-spaces|b' => "highlight spaces at the end of lines" ],
        [ 'version|v'         => "show version number"                  ],
        [ 'help|h'            => "display a usage message"              ],
    );
}

sub validate_args {
    my ($self, $opt, $args) = @_;

    if ($opt->{'help'}) {
        my ($opt, $usage) = describe_options(
            $self->usage_desc(),
            $self->opt_spec(),
        );
        print $usage;
        print "\n";
        print "For more detailed help see 'perldoc App::highlight'\n";
        print "\n";
        exit;
    }
    elsif ($opt->{'version'}) {
        print $App::highlight::VERSION, "\n";
        exit;
    }

    if (!@$args && !$opt->{'show_bad_spaces'}) {
        $self->usage_error(
            "No arguments given!\n" .
            "What do you want me to highlight?\n"
        );
    }

    return;
}

sub execute {
    my ($self, $opt, $args) = @_;

    my @matches;
    if (scalar @$args) {
        if ($opt->{'escape'} || !$opt->{'no_escape'}) {
            @$args = map { "\Q$_" } grep { defined } @$args;
        }
        @matches = @$args;
    }

    my @HIGHLIGHTS;
    if ($COLOR_SUPPORT &&
        ($opt->{'color'} || !$opt->{'no_color'})) {
        @HIGHLIGHTS = @COLORS;
    }
    else {
        @HIGHLIGHTS = @NOCOLORS;
    }

    if (!$COLOR_SUPPORT &&
        ($opt->{'color'} || !$opt->{'no_color'})) {
        my $mod_msg = join(' and ', sort keys %COLOR_MODULES);
        warn "Color support disabled. Install $mod_msg to enable it.\n";
    }

    if ($opt->{'one_color'}) {
        @HIGHLIGHTS = ($HIGHLIGHTS[0]);
    }

    my $ignore_case = '';
    if ($opt->{'ignore_case'}) {
        if ($^V lt v5.14.0) {
            $ignore_case = '(?i)';
        }
        else {
            $ignore_case = '(?^i)';
        }
    }

    while () {
        my $i = 0;
        foreach my $m (@matches) {
            if ($opt->{'full_line'}) {
                if (m/${ignore_case}$m/) {
                    s/^/$HIGHLIGHTS[$i][0]/;
                    s/$/$HIGHLIGHTS[$i][1]/;
                }
            }
            else {
                s/(${ignore_case}$m)/$HIGHLIGHTS[$i][0] . $1 . $HIGHLIGHTS[$i][1]/ge;
            }

            $i++;
            $i %= @HIGHLIGHTS;
        }

        if ($opt->{'show_bad_spaces'}) {
            if ($opt->{'color'} || !$opt->{'no_color'}) {
                s{(\s+)(?=$/)$}{colored($1, "white on_red")}e;
                #s{(\s+)(?=$/)$}{"[start-red]" . $1 . "[end-red]"}e;
            }
            else {
                s{(\s+)(?=$/)$}{"X" x length($1)}e;
            }
        }

        print;
    }

    return;
}

1;

__END__