File Coverage

blib/lib/App/datasection/Command/diff.pm

Criterion	Covered	Total	%
statement	58	60	96.6
branch	8	12	66.6
condition			n/a
subroutine	11	11	100.0
pod	1	1	100.0
total	78	84	92.8

use warnings;
use 5.020;
use experimental qw( signatures );
use stable qw( postderef );
use true;

package App::datasection::Command::diff 0.01 {

    # ABSTRACT: Show the differences between the filesystem and Perl source __DATA__ section files
    # VERSION

    use App::datasection -command;
    use Data::Section::Writer 0.04;
    use Path::Tiny qw( path );
    use Text::Diff qw( diff );

    sub execute ($self, $opt, $args) {

        my @files = map { path($_) } @$args;

        my $dir;
        if($opt->{dir}) {
            $dir = path($opt->{dir})->absolute;
        }

        foreach my $file (@files) {
            my $dir = $dir ? $dir : $file->sibling($file->basename . '.data');

            my $tmp = Path::Tiny->tempfile;
            $tmp->spew_raw($file->slurp_raw);

            if(-d $dir) {
                my $dsw = Data::Section::Writer
                    ->new(perl_filename => $tmp);

                $dir->visit(sub ($path, $state) {
                    return if $path->is_dir;
                    if(-B $path) {
                        $dsw->add_file($path->relative($dir), $path->slurp_raw, 'base64');
                    } else {
                        $dsw->add_file($path->relative($dir), $path->slurp_utf8);
                    }
                }, { recurse => 1 });

                $dsw->update_file;
                unless($dsw->unchanged) {
                    my $diff = diff \$file->slurp_utf8, \$tmp->slurp_utf8;
                    chomp $diff;
                    my $from = path('a')->child($file);
                    my $to = path('b')->child($file);
                    say "--- $from";
                    say "+++ $to";
                    say $diff;
                }
            }
        }
    }

}

__END__