| 1 | package App::cpm::Requirement; | ||
| 2 | use v5.24; | ||
| 3 | use warnings; | ||
| 4 | use experimental qw(lexical_subs signatures); | ||
| 5 | |||
| 6 | use App::cpm::version; | ||
| 7 | |||
| 8 | sub new ($class, @argv) { | ||
| 9 | my $self = bless { requirement => [] }, $class; | ||
| 10 | $self->add(@argv) if @argv; | ||
| 11 | $self; | ||
| 12 | } | ||
| 13 | |||
| 14 | sub empty ($self) { | ||
| 15 | $self->{requirement}->@* == 0; | ||
| 16 | } | ||
| 17 | |||
| 18 | sub has ($self, $package) { | ||
| 19 | my ($found) = grep { $_->{package} eq $package } $self->{requirement}->@*; | ||
| 20 | $found; | ||
| 21 | } | ||
| 22 | |||
| 23 | sub add ($self, @argv) { | ||
| 24 | my %package = (@argv, @argv % 2 ? (0) : ()); | ||
| 25 | for my $package (sort keys %package) { | ||
| 26 | my $version_range = $package{$package}; | ||
| 27 | if (my ($found) = grep { $_->{package} eq $package } $self->{requirement}->@*) { | ||
| 28 | my $merged = eval { | ||
| 29 | App::cpm::version::range_merge($found->{version_range}, $version_range); | ||
| 30 | }; | ||
| 31 | if (my $err = $@) { | ||
| 32 | if ($err =~ /illegal requirements/) { | ||
| 33 | $@ = "Couldn't merge version range '$version_range' with '$found->{version_range}' for package '$package'"; | ||
| 34 | warn $@; # XXX | ||
| 35 | return; # should check $@ in caller side | ||
| 36 | } else { | ||
| 37 | die $err; | ||
| 38 | } | ||
| 39 | } | ||
| 40 | $found->{version_range} = $merged; | ||
| 41 | } else { | ||
| 42 | push $self->{requirement}->@*, { package => $package, version_range => $version_range }; | ||
| 43 | } | ||
| 44 | } | ||
| 45 | return 1; | ||
| 46 | } | ||
| 47 | |||
| 48 | sub merge ($self, $other) { | ||
| 49 | $self->add(map { ($_->{package}, $_->{version_range}) } $other->as_array->@*); | ||
| 50 | } | ||
| 51 | |||
| 52 | sub delete ($self, @package) { | ||
| 53 | for my $i (reverse 0 .. $#{ $self->{requirement} }) { | ||
| 54 | my $current = $self->{requirement}[$i]{package}; | ||
| 55 | if (grep { $current eq $_ } @package) { | ||
| 56 | splice $self->{requirement}->@*, $i, 1; | ||
| 57 | } | ||
| 58 | } | ||
| 59 | } | ||
| 60 | |||
| 61 | sub as_array ($self) { | ||
| 62 | $self->{requirement}; | ||
| 63 | } | ||
| 64 | |||
| 65 | 1; |