| 1 | package App::cpm::Builder::Base; | ||
| 2 | use v5.24; | ||
| 3 | use warnings; | ||
| 4 | use experimental qw(lexical_subs signatures); | ||
| 5 | |||
| 6 | use CPAN::DistnameInfo; | ||
| 7 | use Config; | ||
| 8 | use App::cpm::Util qw(DEBUG); | ||
| 9 | use ExtUtils::Install (); | ||
| 10 | use ExtUtils::InstallPaths (); | ||
| 11 | use File::Copy (); | ||
| 12 | use File::Find (); | ||
| 13 | use File::Path (); | ||
| 14 | use File::Spec; | ||
| 15 | use JSON::PP (); | ||
| 16 | |||
| 17 | my sub nonempty ($path) { | ||
| 18 | return if !-d $path; | ||
| 19 | my $found; | ||
| 20 | File::Find::find({ | ||
| 21 | wanted => sub (@) { | ||
| 22 | return if !-f $File::Find::name; | ||
| 23 | return if $File::Find::name =~ /\.exists$/; | ||
| 24 | $found = 1; | ||
| 25 | $File::Find::prune = 1; | ||
| 26 | }, | ||
| 27 | no_chdir => 1, | ||
| 28 | }, $path); | ||
| 29 | return $found; | ||
| 30 | } | ||
| 31 | |||
| 32 | sub new ($class, %args) { | ||
| 33 | $args{distvname} = CPAN::DistnameInfo->new($args{distfile})->distvname; | ||
| 34 | bless \%args, $class; | ||
| 35 | } | ||
| 36 | |||
| 37 | sub meta ($self) { | ||
| 38 | $self->{meta}; | ||
| 39 | } | ||
| 40 | |||
| 41 | sub local_lib ($self) { | ||
| 42 | $self->{local_lib}; | ||
| 43 | } | ||
| 44 | |||
| 45 | sub _prepare_paths_cache ($self) { | ||
| 46 | $self->{libs} = [ | ||
| 47 | grep { nonempty($_) } | ||
| 48 | map { File::Spec->catdir($self->{directory}, qw(blib), $_) } qw(arch lib) | ||
| 49 | ]; | ||
| 50 | $self->{paths} = [ | ||
| 51 | grep { nonempty($_) } | ||
| 52 | map { File::Spec->catdir($self->{directory}, qw(blib), $_) } qw(script bin) | ||
| 53 | ]; | ||
| 54 | return 1; | ||
| 55 | } | ||
| 56 | |||
| 57 | sub libs ($self) { | ||
| 58 | $self->{libs}; | ||
| 59 | } | ||
| 60 | |||
| 61 | sub paths ($self) { | ||
| 62 | $self->{paths}; | ||
| 63 | } | ||
| 64 | |||
| 65 | sub _env_path ($self, $dependency_paths, $include_local_lib_env) { | ||
| 66 | my $local_bin = $self->{local_bin}; | ||
| 67 | if (!$local_bin && $include_local_lib_env) { | ||
| 68 | $local_bin = File::Spec->catdir($self->{local_lib}, "bin"); | ||
| 69 | } | ||
| 70 | join $Config{path_sep}, | ||
| 71 | $dependency_paths->@*, | ||
| 72 | ( $local_bin ? $local_bin : () ), | ||
| 73 | ( $ENV{PATH} ? $ENV{PATH} : () ); | ||
| 74 | } | ||
| 75 | |||
| 76 | sub _env_perl5lib ($self, $dependency_libs, $include_local_lib_env) { | ||
| 77 | my $local_perl5lib = $self->{local_perl5lib}; | ||
| 78 | if (!$local_perl5lib && $include_local_lib_env) { | ||
| 79 | $local_perl5lib = File::Spec->catdir($self->{local_lib}, "lib", "perl5"); | ||
| 80 | } | ||
| 81 | join $Config{path_sep}, | ||
| 82 | $dependency_libs->@*, | ||
| 83 | ( $local_perl5lib ? $local_perl5lib : () ), | ||
| 84 | ( $ENV{PERL5LIB} ? $ENV{PERL5LIB} : ()); | ||
| 85 | } | ||
| 86 | |||
| 87 | sub _set_env ($self, $dependency_libs, $dependency_paths, $include_local_lib_env) { | ||
| 88 | if ($dependency_paths->@* || $self->{local_bin} || $include_local_lib_env) { | ||
| 89 | $ENV{PATH} = $self->_env_path($dependency_paths, $include_local_lib_env); | ||
| 90 | } | ||
| 91 | |||
| 92 | if ($dependency_libs->@* || $self->{local_perl5lib} || $include_local_lib_env) { | ||
| 93 | $ENV{PERL5LIB} = $self->_env_perl5lib($dependency_libs, $include_local_lib_env); | ||
| 94 | } | ||
| 95 | } | ||
| 96 | |||
| 97 | sub _write_blib_meta ($self, $ctx) { | ||
| 98 | return 1 if !defined $self->{distvname}; | ||
| 99 | my $name = $self->meta->{name}; | ||
| 100 | $name =~ s/-/::/g; | ||
| 101 | |||
| 102 | my %provides = map { | ||
| 103 | my $package = $_->{package}; | ||
| 104 | my %info; | ||
| 105 | $info{file} = $_->{file}; | ||
| 106 | $info{version} = $_->{version} if $_->{version}; | ||
| 107 | ($package, \%info); | ||
| 108 | } $self->{provides}->@*; | ||
| 109 | |||
| 110 | my %install = ( | ||
| 111 | name => $name, | ||
| 112 | target => $name, | ||
| 113 | version => $self->meta->{version}, | ||
| 114 | dist => $self->{distvname}, | ||
| 115 | pathname => $self->{distfile}, | ||
| 116 | provides => \%provides, | ||
| 117 | ); | ||
| 118 | |||
| 119 | File::Path::mkpath("blib/meta", 0, 0777); | ||
| 120 | { | ||
| 121 | open my $fh, ">", "blib/meta/install.json" or die $!; | ||
| 122 | print {$fh} JSON::PP->new->canonical->pretty->encode(\%install); | ||
| 123 | close $fh; | ||
| 124 | } | ||
| 125 | |||
| 126 | File::Copy::copy("MYMETA.json", "blib/meta/MYMETA.json") or die $!; | ||
| 127 | return 1; | ||
| 128 | } | ||
| 129 | |||
| 130 | sub _install_paths ($self) { | ||
| 131 | ExtUtils::InstallPaths->new( | ||
| 132 | dist_name => $self->meta->name, | ||
| 133 | ($self->{install_base} ? (install_base => $self->{install_base}) : ()), | ||
| 134 | ); | ||
| 135 | } | ||
| 136 | |||
| 137 | sub _install_blib ($self, $ctx) { | ||
| 138 | open my $fh, ">", \my $stdout; | ||
| 139 | { | ||
| 140 | local *STDOUT = $fh; | ||
| 141 | ExtUtils::Install::install($self->_install_paths->install_map, 0, 0, 0); | ||
| 142 | } | ||
| 143 | $ctx->log($stdout) if defined $stdout; | ||
| 144 | return 1; | ||
| 145 | } | ||
| 146 | |||
| 147 | sub _install_blib_meta ($self, $ctx) { | ||
| 148 | return 1 if !defined $self->{distvname}; | ||
| 149 | |||
| 150 | my $install_base = $self->{install_base}; | ||
| 151 | my $install_base_meta = $install_base ? File::Spec->catdir($install_base, "lib", "perl5") : $Config{sitelibexp}; | ||
| 152 | my $meta_target_dir = File::Spec->catdir($install_base_meta, $Config{archname}, ".meta", $self->{distvname}); | ||
| 153 | |||
| 154 | open my $fh, ">", \my $stdout; | ||
| 155 | { | ||
| 156 | local *STDOUT = $fh; | ||
| 157 | ExtUtils::Install::install({ | ||
| 158 | 'blib/meta' => $meta_target_dir, | ||
| 159 | }); | ||
| 160 | } | ||
| 161 | $ctx->log($stdout) if defined $stdout; | ||
| 162 | return 1; | ||
| 163 | } | ||
| 164 | |||
| 165 | sub install ($self, $ctx, $dependency_libs = [], $dependency_paths = []) { | ||
| 166 | $self->_install_blib($ctx); | ||
| 167 | $self->_install_blib_meta($ctx); | ||
| 168 | return 1; | ||
| 169 | } | ||
| 170 | |||
| 171 | sub needs_install_env ($self) { | ||
| 172 | return 0; | ||
| 173 | } | ||
| 174 | |||
| 175 | sub _log_env ($self, $ctx) { | ||
| 176 | if (exists $ENV{PERL5LIB}) { | ||
| 177 | $ctx->log("PERL5LIB: $_") for split /\Q$Config{path_sep}\E/, $ENV{PERL5LIB}; | ||
| 178 | } | ||
| 179 | if (exists $ENV{PATH}) { | ||
| 180 | $ctx->log("PATH: $_") for split /\Q$Config{path_sep}\E/, $ENV{PATH}; | ||
| 181 | } | ||
| 182 | } | ||
| 183 | |||
| 184 | sub _use_unsafe_inc ($self, $ctx) { | ||
| 185 | if (exists $ENV{PERL_USE_UNSAFE_INC}) { | ||
| 186 | return $ENV{PERL_USE_UNSAFE_INC}; | ||
| 187 | } | ||
| 188 | if (exists $self->meta->{x_use_unsafe_inc}) { | ||
| 189 | $ctx->log("Distribution opts in x_use_unsafe_inc: $self->{meta}{x_use_unsafe_inc}"); # XXX | ||
| 190 | return $self->meta->{x_use_unsafe_inc}; | ||
| 191 | } | ||
| 192 | 1; | ||
| 193 | } | ||
| 194 | |||
| 195 | sub run_configure ($self, $ctx, $cmd, $dependency_libs, $dependency_paths) { | ||
| 196 | local %ENV = %ENV; | ||
| 197 | $ENV{PERL5_CPAN_IS_RUNNING} = $$; | ||
| 198 | $ENV{PERL5_CPANPLUS_IS_RUNNING} = $$; | ||
| 199 | $ENV{PERL5_CPANM_IS_RUNNING} = $$; | ||
| 200 | $ENV{PERL_MM_USE_DEFAULT} = 1; | ||
| 201 | $ENV{PERL_USE_UNSAFE_INC} = $self->_use_unsafe_inc($ctx); | ||
| 202 | $self->_set_env($dependency_libs, $dependency_paths, 0); | ||
| 203 | DEBUG and $self->_log_env($ctx); | ||
| 204 | $ctx->run_command($cmd, $self->{configure_timeout}); | ||
| 205 | } | ||
| 206 | |||
| 207 | sub run_build ($self, $ctx, $cmd, $dependency_libs, $dependency_paths) { | ||
| 208 | local %ENV = %ENV; | ||
| 209 | $ENV{PERL_MM_USE_DEFAULT} = 1; | ||
| 210 | $ENV{PERL_USE_UNSAFE_INC} = $self->_use_unsafe_inc($ctx); | ||
| 211 | $self->_set_env($dependency_libs, $dependency_paths, 0); | ||
| 212 | DEBUG and $self->_log_env($ctx); | ||
| 213 | $ctx->run_command($cmd, $self->{build_timeout}); | ||
| 214 | } | ||
| 215 | |||
| 216 | sub run_install ($self, $ctx, $cmd, $dependency_libs, $dependency_paths) { | ||
| 217 | local %ENV = %ENV; | ||
| 218 | $ENV{PERL_MM_USE_DEFAULT} = 1; | ||
| 219 | $ENV{PERL_USE_UNSAFE_INC} = $self->_use_unsafe_inc($ctx); | ||
| 220 | $self->_set_env($dependency_libs, $dependency_paths, $self->{local_lib} ? 1 : 0); | ||
| 221 | DEBUG and $self->_log_env($ctx); | ||
| 222 | $ctx->run_command($cmd, 0); | ||
| 223 | } | ||
| 224 | |||
| 225 | sub run_test ($self, $ctx, $cmd, $dependency_libs, $dependency_paths) { | ||
| 226 | local %ENV = %ENV; | ||
| 227 | $ENV{PERL_MM_USE_DEFAULT} = 1; | ||
| 228 | $ENV{PERL_USE_UNSAFE_INC} = $self->_use_unsafe_inc($ctx); | ||
| 229 | $ENV{NONINTERACTIVE_TESTING} = 1; | ||
| 230 | $self->_set_env($dependency_libs, $dependency_paths, 0); | ||
| 231 | DEBUG and $self->_log_env($ctx); | ||
| 232 | $ctx->run_command($cmd, $self->{test_timeout}); | ||
| 233 | } | ||
| 234 | |||
| 235 | 1; |