File Coverage

blib/lib/App/bif/init.pm

Criterion	Covered	Total	%
statement	36	43	83.7
branch	4	12	33.3
condition	0	3	0.0
subroutine	8	8	100.0
pod	1	2	50.0
total	49	68	72.0

package App::bif::init;
use strict;
use warnings;
use Bif::Mo;
use Path::Tiny qw/cwd path/;

our $VERSION = '0.1.5_7';
extends 'App::bif';

sub init_user_repo {
    my $self         = shift;
    my $keep_invalid = shift;

    require File::HomeDir;
    my $user_repo = path( File::HomeDir->my_home )->child('.bifu');
    return if $user_repo->is_dir;

    $self->dispatch(
        'App::bif::new::repo',
        opts   => { config => 1, directory => $user_repo },
        subref => sub {

            # This $self is a new_repo with a valid db handle
            my $self          = shift;
            my $major_version = shift;
            my $minor_version = shift;

            $self->dbw->xdo(
                insert_into => 'bifkv',
                values      => {
                    key      => 'keep_invalid',
                    bool_val => $keep_invalid,
                },
            );

            $self->dispatch( 'App::bif::new::identity', opts => { self => 1 } );
        },
    );
}

sub run {
    my $self = shift;
    my $opts = $self->opts;

    my $dir;
    my $name;
    if ( $opts->{directory} ) {
        $opts->{directory} .= '.bifhub'
          unless $opts->{directory} =~ m/\.bifhub$/;
        $dir  = path( $opts->{directory} );
        $name = $dir->basename;
        $dir  = $dir->parent->realpath->child($name);
    }
    else {
        $dir = cwd->child('.bif');
    }

    return $self->err( 'DirExists', 'directory exists: ' . $dir )
      if -e $dir;

    $self->init_user_repo( $opts->{keep_invalid} );

    $self->dispatch(
        'App::bif::new::repo',
        opts   => { directory => $dir },
        subref => sub {

            # This $self is a new_repo with a valid db handle
            my $self          = shift;
            my $major_version = shift;
            my $minor_version = shift;

            $self->dbw->xdo(
                insert_into => 'bifkv',
                values      => {
                    key      => 'keep_invalid',
                    bool_val => $opts->{keep_invalid},
                },
            );

            $self->dispatch(
                'App::bif::pull::identity',
                opts => {
                    location => $self->user_repo,
                    self     => 1,
                },
            );

            $self->dispatch(
                'App::bif::new::hub',
                opts => {
                    name     => $name,
                    title    => $opts->{title} || $name,
                    location => $dir,
                    default  => 1,
                }
            ) if $opts->{directory};
        },
    );

    return $self->ok('InitHub') if $opts->{directory};
    return $self->ok('Init');
}

1;
__END__