File Coverage

blib/lib/App/bif/pull/identity.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package App::bif::pull::identity;
use strict;
use warnings;
use AnyEvent;
use Bif::Sync::Client;
use Bif::Mo;
use Coro;
use DBIx::ThinSQL qw/qv/;
use Log::Any '$log';

our $VERSION = '0.1.5_6';
extends 'App::bif';

sub run {
    my $self = shift;
    my $opts = $self->opts;
    my $cv   = AE::cv;
    my $dbw  = $self->dbw;

    $opts->{message} ||= "Importing identity from $opts->{location}";

    $|++;

    my $error;
    my $client = Bif::Sync::Client->new(
        name          => $opts->{location},
        db            => $dbw,
        location      => $opts->{location},
        debug         => $opts->{debug},
        debug_bifsync => $opts->{debug_bifsync},
        on_update     => sub {
            my $client = shift;
            $self->lprint( $client->name . ': ' . $_[0] );
        },
        on_error => sub {
            $error = shift;
            $cv->send;
        },
    );

    my $fh   = select;
    my $coro = async {
        select $fh;

        eval {
            $dbw->txn(
                sub {
                    my $start = time;

                    $|++;
                    my $status = $client->bootstrap_identity;

                    unless ( $status eq 'IdentityImported' ) {
                        $dbw->rollback;
                        $error =
"unexpected IdentityImported status received: $status";
                        return;
                    }

                    my ( $iid, $uuid, $name, $sn ) = $dbw->xlist(
                        select => [
                            'bifkv.identity_id',
                            '"u" || substr(n.uuid,1,8) AS uuid',
                            'e.name', 'i.shortname',
                        ],
                        from       => 'bifkv',
                        inner_join => 'nodes n',
                        on         => 'n.id = bifkv.identity_id',
                        inner_join => 'identities i',
                        on         => 'i.id = n.id',
                        inner_join => 'entities e',
                        on         => 'e.id = i.id',
                        where      => { key => 'self' },
                    );

                    $self->start_work(
                        node_id       => $iid,
                        start         => $start,
                        start_comment => 'pull identity',
                        stop          => time,
                        billable      => 0,
                    );

                    print "\n";
                }
            );
        };

        if ($@) {
            $error = $@;
            print "\n";
        }

        return $cv->send;
    };

    $cv->recv;
    $client->disconnect;
    return $self->err( 'Unknown', $error ) if $error;
    return $self->ok('PullIdentity');
}

1;
__END__