File Coverage

bin/ypick

Criterion	Covered	Total	%
statement	39	43	90.7
branch	12	16	75.0
condition	3	3	100.0
subroutine	6	6	100.0
pod			n/a
total	60	68	88.2

#!/usr/bin/env perl
package ypick;
# ABSTRACT: pick a data structure to display only the desired fields
$ypick::VERSION = '0.013';
use App::YAML::Filter::Base;
use Pod::Usage::Return qw( pod2usage );
use Getopt::Long qw( GetOptionsFromArray );
use YAML;
use Data::Partial::Google;

$|++; # no buffering

sub main {
    my ( $class, @argv ) = @_;
    my %opt;
    GetOptionsFromArray( \@argv, \%opt,
        'help|h',
        'version',
    );
    return pod2usage(0) if $opt{help};
    if ( $opt{version} ) {
        print "ypick version $ypick::VERSION (Perl $^V)\n";
        return 0;
    }

    my $pick = shift @argv;
    return pod2usage("ERROR: Must give a pick") unless $pick;

    my $filter = Data::Partial::Google->new( $pick );

    push @argv, "-" unless @argv;
    for $ARGV ( @argv ) {
        # We're doing a similar behavior to <>, but manually for easier testing.
        my $fh;
        if ( $ARGV eq '-' ) {
            # Use the existing STDIN so tests can fake it
            $fh = \*STDIN;
        }
        else {
            unless ( open $fh, '<', $ARGV ) {
                warn "Could not open file '$ARGV' for reading: $!\n";
                next;
            }
        }

        my $buffer;
        my $scope = {};
        while ( my $line = <$fh> ) {
            # --- is the start of a new document
            if ( $buffer && $line =~ /^---/ ) {
                # Flush the previous document
                print YAML::Dump( $filter->mask( YAML::Load( $buffer ) ) );
                $buffer = '';
            }
            $buffer .= $line;
        }
        # Flush the buffer in the case of a single document with no ---
        if ( $buffer =~ /\S/ ) {
            #print STDERR "Buffer is: $buffer\n";
            print YAML::Dump( $filter->mask( YAML::Load( $buffer ) ) );
        }
    }

    return 0;
}

exit __PACKAGE__->main( @ARGV ) unless caller(0);

__END__