File Coverage

blib/lib/App/Software/License.pm

Criterion	Covered	Total	%
statement	38	41	92.6
branch	5	6	83.3
condition	10	14	71.4
subroutine	10	11	90.9
pod	0	2	0.0
total	63	74	85.1

package App::Software::License; # git description: v0.10-4-g9e7e1ff
# ABSTRACT: Command-line interface to Software::License
# KEYWORDS: license licence LICENSE generate distribution build tool

our $VERSION = '0.11';

use Moo 1.001000;
use MooX::Options;
use File::HomeDir;
use File::Spec::Functions qw/catfile/;
use Module::Runtime qw/use_module/;
use Software::License;
use Config::Any;

use namespace::autoclean 0.16 -except => [qw/_options_data _options_config/];

#pod =head1 SYNOPSIS
#pod
#pod     software-license --holder 'J. Random Hacker' --license Perl_5 --type notice
#pod
#pod =head1 DESCRIPTION
#pod
#pod This module provides a command-line interface to Software::License. It can be
#pod used to easily produce license notices to be included in other documents.
#pod
#pod All the attributes documented below are available as command-line options
#pod through L and can also be configured in
#pod F<$HOME/.software_license.conf> through L.
#pod
#pod =cut

#pod =attr holder
#pod
#pod Name of the license holder.
#pod
#pod =cut

option holder => (
    is       => 'ro',
    required => 1,
    format   => 's',
    doc => '',
);

#pod =attr year
#pod
#pod Year to be used in the copyright notice.
#pod
#pod =cut

option year => (
    is     => 'ro',
    format => 'i',
    doc => '',
);

#pod =attr license
#pod
#pod Name of the license to use. Must be the name of a module available under the
#pod Software::License:: namespace. Defaults to Perl_5.
#pod
#pod =cut

option license => (
    is      => 'ro',
    default => 'Perl_5',
    format  => 's',
    doc => '',
);

#pod =attr type
#pod
#pod The type of license notice you'd like to generate. Available values are:
#pod
#pod B<* notice>
#pod
#pod This method returns a snippet of text, usually a few lines, indicating the
#pod copyright holder and year of copyright, as well as an indication of the license
#pod under which the software is distributed.
#pod
#pod B<* license>
#pod
#pod This method returns the full text of the license.
#pod
#pod =for :stopwords fulltext
#pod
#pod B<* fulltext>
#pod
#pod This method returns the complete text of the license, preceded by the copyright
#pod notice.
#pod
#pod B<* version>
#pod
#pod =for :stopwords versioned
#pod
#pod This method returns the version of the license.  If the license is not
#pod versioned, this returns nothing.
#pod
#pod B<* meta_yml_name>
#pod
#pod This method returns the string that should be used for this license in the CPAN
#pod META.yml file, or nothing if there is no known string to use.
#pod
#pod =for Pod::Coverage run
#pod
#pod =for Pod::Coverage BUILDARGS
#pod
#pod =cut

option type => (
    is      => 'ro',
    default => 'notice',
    format => 's',
    doc => '',
);

#pod =attr configfile
#pod
#pod Path to the optional configuration file. Defaults to C<$HOME/.software_license.conf>.
#pod
#pod =cut

option configfile => (
    is => 'ro',
    default => catfile(File::HomeDir->my_home, '.software_license.conf'),
    format => 's',
    doc => '',
    order => 100,
);

has _software_license => (
    is      => 'ro',
    isa     => sub { die "Not a Software::License" if !$_[0]->isa('Software::License') },
    lazy    => 1,
    builder => '_build__software_license',
    handles => {
        notice   => 'notice',
        text     => 'license',
        fulltext => 'fulltext',
        version  => 'version',
    },
);

sub _build__software_license {
    my ($self) = @_;
    my $class = "Software::License::${\$self->license}";

    return use_module($class)->new({
        holder => $self->holder,
        year   => $self->year,
    });
}

sub BUILDARGS {
    my $class = shift;

    my $args = { @_ };
    my $configfile = $args->{configfile} || catfile(File::HomeDir->my_home, '.software_license.conf');

    # Handling license as a trailing non-option argument
    if (!exists $args->{license}
            && scalar @ARGV && $ARGV[-1] !~ m{^--.+=.+}
            && (!scalar (@_) || $ARGV[-1] ne $_[-1])
    ) {
        $args->{license} = $ARGV[-1];
    }

    if (-e $configfile) {
        my $conf = Config::Any->load_files({ files => [$configfile], use_ext => 1, flatten_to_hash => 1 })->{ $configfile };
        $args = { %{ $conf || {} }, %$args };
    }
    return $args;
}

sub run {
    my ($self) = @_;
    my $meth = $self->type;
    print $self->_software_license->$meth;
}

1;

__END__