File Coverage

blib/lib/App/Schema/Deploy.pm

Criterion	Covered	Total	%
statement	35	53	66.0
branch	3	14	21.4
condition	6	6	100.0
subroutine	7	7	100.0
pod	2	2	100.0
total	53	82	64.6

package App::Schema::Deploy;

use strict;
use warnings;

use English;
use Error::Pure qw(err);
use Getopt::Std;

our $VERSION = 0.01;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Object.
	return $self;
}

# Run.
sub run {
	my $self = shift;

	# Process arguments.
	$self->{'_opts'} = {
		'h' => 0,
		'p' => '',
		'u' => '',
		'v' => undef,
	};
	if (! getopts('hp:u:v:', $self->{'_opts'})
		|| $self->{'_opts'}->{'h'}
		|| @ARGV < 2) {

		print STDERR "Usage: $0 [-h] [-p password] [-u user] [-v schema_version] ".
			"[--version] dsn schema_module\n";
		print STDERR "\t-h\t\t\tPrint help.\n";
		print STDERR "\t-p password\t\tDatabase password.\n";
		print STDERR "\t-u user\t\t\tDatabase user.\n";
		print STDERR "\t-v schema_version\tSchema version (default is ".
			"latest version).\n";
		print STDERR "\t--version\t\tPrint version.\n";
		print STDERR "\tdsn\t\t\tDatabase DSN. e.g. dbi:SQLite:dbname=ex1.db\n";
		print STDERR "\tschema_module\t\tName of Schema module.\n";
		return 1;
	}
	$self->{'_dsn'} = shift @ARGV;
	$self->{'_schema_module'} = shift @ARGV;

	eval "require $self->{'_schema_module'}";
	if ($EVAL_ERROR) {
		err 'Cannot load Schema module.',
			'Module name', $self->{'_schema_module'},
			'Error', $EVAL_ERROR,
		;
	}

	my $schema_module;
	my $schema_version;
	if ($self->{'_schema_module'}->can('new')) {
		my $versioned_schema = $self->{'_schema_module'}->new(
			$self->{'_opts'}->{'v'} ? (
				'version' => $self->{'_opts'}->{'v'},
			) : (),
		);
		$schema_module = $versioned_schema->schema;
		$schema_version = $versioned_schema->version;

	} else {
		$schema_module = $self->{'_schema_module'};
	}

	my $schema = eval {
		$schema_module->connect($self->{'_dsn'},
			$self->{'_opts'}->{'u'}, $self->{'_opts'}->{'p'}, {});
	};
	if ($EVAL_ERROR) {
		err 'Cannot connect to Schema database.',
			'Error', $EVAL_ERROR,
		;
	}
	if (! $schema->isa('DBIx::Class::Schema')) {
		err "Instance of schema must be a 'DBIx::Class::Schema' object.",
			'Reference', $schema->isa,
		;
	}

	# Deploy.
	$schema->deploy;

	my $print_version = '';
	if (defined $schema_version) {
		$print_version = '(v'.$schema_version.') ';
	}
	print "Schema ${print_version}from '$self->{'_schema_module'}' was ".
		"deployed to '$self->{'_dsn'}'.\n";

	return 0;
}

1;


__END__