File Coverage

blib/lib/App/PerlWatcher/Watcher/Ping.pm

Criterion	Covered	Total	%
statement	53	56	94.6
branch	5	6	83.3
condition	0	5	0.0
subroutine	18	19	94.7
pod	0	2	0.0
total	76	88	86.3

package App::PerlWatcher::Watcher::Ping;
{
  $App::PerlWatcher::Watcher::Ping::VERSION = '0.20';
}
# ABSTRACT: Watches for host availablity via pingig it (ICMP) or knoking to it's port (TCP)

use 5.12.0;
use strict;
use warnings;

use AnyEvent::Socket;
use AnyEvent::Util;
use App::PerlWatcher::Watcher;
use Carp;
use Smart::Comments -ENV;
use Moo;
use Net::Ping::External qw(ping);



has 'host'              => ( is => 'ro', required => 1 );


has 'port'              => ( is => 'ro', required => 0 );


has 'frequency'         => ( is => 'ro', default => sub{ 60; } );


has 'timeout'           => ( is => 'lazy');
has 'watcher_callback'  => ( is => 'lazy');

with qw/App::PerlWatcher::Watcher/;

sub _build_timeout {
    $_[0]->config->{timeout} // $_[0]->engine_config->{defaults}->{timeout} // 5;
}

sub _build_watcher_callback {
    my $self = shift;
    $self -> {_watcher} = $self->port
        ? $self->_tcp_watcher_callback
        : $self->_icmp_watcher_callback;
}

sub _icmp_watcher_callback {
    my $self = shift;
    my $host = $self->host;
    my $timeout = $self->timeout;
    return sub {
        $self->poll_callback->($self);
        fork_call {
            my $alive = ping(host => $host, timeout => $timeout);
            $alive;
        } sub {
            my $success = shift;
            $self->interpret_result( $success, $self->callback);
        };
    }
}

sub _tcp_watcher_callback {
    my $self = shift;
    my ($host, $port ) = ( $self->host, $self->port );
    return sub {
        $self->poll_callback->($self);
        tcp_connect $host, $port, sub {
            my $success = @_ != 0;
            # $! contains error
            # $host
            # $success
            $self->interpret_result( $success, $self->callback);
          }, sub {

            #connect timeout
            #my ($fh) = @_;

            1;
          };
    };
}

sub build_watcher_guard {
    my $self = shift;
    return AnyEvent->timer(
        after    => 0,
        interval => $self->frequency,
        cb       => sub {
            $self->watcher_callback->()
              if $self->active;
        }
    );
}

sub description {
    my $self = shift;
    my $description = $self->port
        ? "Knocking at " . $self->host . ":" . $self->port
        : "Ping " . $self->host;
}


1;

__END__