File Coverage

blib/lib/App/OverWatch/Notify.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package App::OverWatch::Notify;
# ABSTRACT: Notify base class

use strict;
use warnings;
use utf8;

use App::OverWatch::DB;
use App::OverWatch::Notification;

use Module::Load qw( load );

sub new {
    my $class = shift;
    my $rh_options = shift || {};

    my $DB = $rh_options->{db} // die "Require 'db'";

    my $type = $DB->type();

    my $subclass = $class . '::' . $type;
    load($subclass);

    my $self = bless( {}, $subclass );

    $self->{DB} = $DB;

    return $self;
}

sub create_notification {
    my $self    = shift;
    my $rh_args = shift;

    my $system    = $rh_args->{system}    || die "Error: require 'system'";
    my $subsystem = $rh_args->{subsystem} || die "Error: require 'subsystem'";
    my $worker    = $rh_args->{worker}    || die "Error: require 'worker'";

    my $sql =<<"SQL";
INSERT INTO
    notifications ( system, subsystem, worker, ctime, mtime )
VALUES
    ( ?, ?, ?, NOW(), NOW() )
SQL

    my $ret = $self->{DB}->dbix_run( $sql, $system, $subsystem, $worker );
    return $ret;
}

sub delete_notification {
    my $self    = shift;
    my $rh_args = shift;

    my $system    = $rh_args->{system}    || die "Error: require 'system'";
    my $subsystem = $rh_args->{subsystem} || die "Error: require 'subsystem'";
    my $worker    = $rh_args->{worker}    || die "Error: require 'worker'";

    my $sql =<<"SQL";
DELETE FROM
    notifications
WHERE
    system = ? AND
    subsystem = ? AND
    worker = ?
SQL

    my $ret = $self->{DB}->dbix_run( $sql, $system, $subsystem, $worker );
    return $ret;
}

sub delete_all_notifications {
    my $self    = shift;
    my $rh_args = shift;

    my $worker    = $rh_args->{worker} || die "Error: require 'worker'";

    my $sql =<<"SQL";
DELETE FROM
    notifications
WHERE
    worker = ?
SQL

    my $ret = $self->{DB}->dbix_run( $sql, $worker );
    return $ret;
}

sub check_notifications {
    my $self    = shift;
    my $rh_args = shift;

    my $worker    = $rh_args->{worker} || die "Error: require 'worker'";

    my $sql =<<"SQL";
SELECT
    *
FROM
    notifications
WHERE
    worker = ?
SQL

    my $sth = $self->{DB}->dbix_select( $sql );
    return undef if (!defined($sth));
    my @notifications;
    while ( my $rh_row = $sth->fetchrow_hashref() ) {
        my $Notification = App::OverWatch::Notification->new($rh_row);
        push(@notifications, $Notification);
    }
    return \@notifications;
}

sub notify {
    my $self    = shift;
    my $rh_args = shift;

    my $system    = $rh_args->{system}    || die "Error: require 'system'";
    my $subsystem = $rh_args->{subsystem} || die "Error: require 'subsystem'";
    my $text      = $rh_args->{text}      || die "Error: require 'text'";

    my $sql =<<"SQL";
UPDATE
    notifications
SET
    fired = 1,
    text = ?,
    mtime = NOW()
WHERE
    system = ? AND
    subsystem = ?
SQL

    my $ret = $self->{DB}->dbix_run( $sql, $text, $system, $subsystem);
    return $ret;
}

1;

__END__