File Coverage

blib/lib/App/Nopaste/Service/PastebinComAPI.pm

Criterion	Covered	Total	%
statement	12	27	44.4
branch	0	12	0.0
condition	0	9	0.0
subroutine	4	6	66.6
pod	1	2	50.0
total	17	56	30.3

package App::Nopaste::Service::PastebinComAPI;

use 5.006;
use strict;
use warnings FATAL => 'all';
use base 'App::Nopaste::Service';

our $VERSION = '1.002';

sub available {
    eval 'require WWW::Pastebin::PastebinCom::API; 1';
}
sub run {
    my $self = shift;
    my %args = @_;

    my ( $api_key, $user_key ) = @ENV{qw/
        APP_NOPASTE_PASTEBINCOM_API_KEY
        APP_NOPASTE_PASTEBINCOM_USER_KEY
    /};

    unless ( defined $api_key and length $api_key
        and defined $user_key and length $user_key
    ) {
        return (0,'You must specify the pastebin.com API keys'
            . ' using the APP_NOPASTE_PASTEBINCOM_API_KEY and'
            . ' APP_NOPASTE_PASTEBINCOM_USER_KEY environmental'
            . ' variables! To generate your user key, run this piece of'
            . ' code: '
            . q{perl -MWWW::Pastebin::PastebinCom::API -wle "print }
            . q{WWW::Pastebin::PastebinCom::API->new( api_key => }
            . q{ q|YOUR_API_KEY_HERE|)->get_user_key(qw/ }
            . q{YOUR_PASTEBIN_LOGIN_HERE  YOUR_PASTEBIN_PASSWORD_HERE/);"}
        );
    }

    require WWW::Pastebin::PastebinCom::API;

    my $bin = WWW::Pastebin::PastebinCom::API->new(
        api_key  => $api_key,
        user_key => $user_key,
    );

    delete $args{nick} if defined $args{nick};
    $args{title}  = delete $args{desc} if defined $args{desc};
    $args{format} = delete $args{lang} if defined $args{lang};
    $args{unlisted} = 1 unless $args{private};

    my $ok = $bin->paste(
        delete($args{text}),
        expiry => 'm1',
        %args,
    );

    return (0, $bin->error) unless $ok;
    return (1, $bin->paste_url);
}



q|
Q: How many programmers does it take to change a light bulb?
A: None. It's a hardware problem.
|;

__END__